#687169 (Crystal) No.1640 簡単な色塗り

提出ソース

結果

問題	No.1640 簡単な色塗り
ユーザー	yuruhiya
提出日時	2021-08-07 12:21:43
言語	Crystal (1.11.2)
結果	AC
実行時間	206 ms / 2,000 ms
コード長	18,516 bytes
コンパイル時間	22,007 ms
コンパイル使用メモリ	265,260 KB
実行使用メモリ	61,384 KB
最終ジャッジ日時	2023-09-12 03:47:22
合計ジャッジ時間	31,266 ms
ジャッジサーバーID （参考情報）	judge13 / judge15

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	2 ms 4,384 KB
testcase_01	AC	3 ms 4,572 KB
testcase_02	AC	2 ms 4,400 KB
testcase_03	AC	2 ms 4,384 KB
testcase_04	AC	206 ms 61,384 KB
testcase_05	AC	92 ms 35,084 KB
testcase_06	AC	3 ms 4,508 KB
testcase_07	AC	2 ms 4,516 KB
testcase_08	AC	2 ms 4,576 KB
testcase_09	AC	3 ms 4,492 KB
testcase_10	AC	77 ms 21,536 KB
testcase_11	AC	67 ms 19,328 KB
testcase_12	AC	59 ms 18,496 KB
testcase_13	AC	135 ms 30,200 KB
testcase_14	AC	143 ms 30,404 KB
testcase_15	AC	44 ms 12,168 KB
testcase_16	AC	55 ms 16,104 KB
testcase_17	AC	100 ms 25,448 KB
testcase_18	AC	10 ms 6,836 KB
testcase_19	AC	56 ms 18,272 KB
testcase_20	AC	73 ms 21,104 KB
testcase_21	AC	66 ms 19,236 KB
testcase_22	AC	8 ms 5,892 KB
testcase_23	AC	83 ms 22,660 KB
testcase_24	AC	23 ms 8,672 KB
testcase_25	AC	60 ms 18,340 KB
testcase_26	AC	95 ms 23,376 KB
testcase_27	AC	39 ms 12,092 KB
testcase_28	AC	133 ms 31,608 KB
testcase_29	AC	94 ms 24,040 KB
testcase_30	AC	15 ms 8,036 KB
testcase_31	AC	99 ms 32,976 KB
testcase_32	AC	85 ms 27,588 KB
testcase_33	AC	56 ms 20,124 KB
testcase_34	AC	70 ms 24,696 KB
testcase_35	AC	57 ms 19,804 KB
testcase_36	AC	16 ms 8,112 KB
testcase_37	AC	19 ms 9,504 KB
testcase_38	AC	83 ms 26,876 KB
testcase_39	AC	39 ms 13,688 KB
testcase_40	AC	45 ms 14,632 KB
testcase_41	AC	80 ms 24,420 KB
testcase_42	AC	42 ms 14,572 KB
testcase_43	AC	44 ms 14,812 KB
testcase_44	AC	44 ms 14,828 KB
testcase_45	AC	32 ms 12,524 KB
testcase_46	AC	18 ms 8,832 KB
testcase_47	AC	11 ms 7,108 KB
testcase_48	AC	91 ms 27,880 KB
testcase_49	AC	6 ms 5,676 KB
testcase_50	AC	3 ms 4,428 KB
testcase_51	AC	2 ms 4,444 KB
testcase_52	AC	145 ms 38,500 KB
testcase_53	AC	152 ms 38,592 KB
07_evil_01.txt	AC	351 ms 68,240 KB
07_evil_02.txt	AC	504 ms 86,892 KB

権限があれば一括ダウンロードができます

ソースコード

raw source code

# require "/template"
# require "./scanner"
# ### Specifications
#
# ```plain
# Inside input macro                            | Expanded code
# ----------------------------------------------+---------------------------------------
# Uppercase string: Int32, Int64, Float64, etc. | {}.new(Scanner.s)
# s                                             | Scanner.s
# c                                             | Scanner.c
# Other lowercase string: i, i64, f, etc.       | Scanner.s.to_{}
# operator[]: type[size]                        | Array.new(input(size)) { input(type) }
# Tuple literal: {t1, t2, t3}                   | {input(t1), input(t2), input(t3)}
# Array literal: [t1, t2, t3]                   | [input(t1), input(t2), input(t3)]
# Range literal: t1..t2                         | input(t1)..input(t2)
# If: cond ? t1 : t2                            | cond ? input(t1) : input(t2)
# Assign: target = value                        | target = input(value)
# ```
#
# ### Examples
#
# Input:
# ```plain
# 5 3
# foo bar
# 1 2 3 4 5
# ```
# ```
# n, m = input(Int32, Int64) # => {5, 10i64}
# input(String, Char[m])     # => {"foo", ['b', 'a', 'r']}
# input(Int32[n])            # => [1, 2, 3, 4, 5]
# ```
# ```
# n, m = input(i, i64) # => {5, 10i64}
# input(s, c[m])       # => {"foo", ['b', 'a', 'r']}
# input(i[n])          # => [1, 2, 3, 4, 5]
# ```
#
# Input:
# ```plain
# 2 3
# 1 2 3
# 4 5 6
# ```
#
# ```
# h, w = input(i, i) # => {2, 3}
# input(i[h, w])     # => [[1, 2, 3], [4, 5, 6]]
# ```
# ```
# input(i[i][i]) # => [[1, 2, 3], [4, 5, 6]]
# ```
#
# Input:
# ```plain
# 5 3
# 3 1 4 2 5
# 1 2
# 2 3
# 3 1
# ```
# ```
# n, m = input(i, i)       # => {5, 3}
# input(i.pred[n])         # => [2, 0, 3, 1, 4]
# input({i - 1, i - 1}[m]) # => [{0, 1}, {1, 2}, {2, 0}]
# ```
#
# Input:
# ```plain
# 3
# 1 2
# 2 2
# 3 2
# ```
# ```
# input({tmp = i, tmp == 1 ? i : i.pred}[i]) # => [{1, 2}, {2, 1}, {3, 1}]
# ```
#
# Input:
# ```plain
# 3
# 1 2
# 2 3
# 3 1
# ```
# ```
# n = input(i)
# input_column({Int32, Int32}, n) # => {[1, 2, 3], [2, 3, 1]}
# ```
class Scanner
  private def self.skip_to_not_space
    peek = STDIN.peek
    not_space = peek.index { |x| x != 32 && x != 10 } || peek.size
    STDIN.skip(not_space)
  end

  def self.c
    skip_to_not_space
    STDIN.read_char.not_nil!
  end

  def self.s
    skip_to_not_space

    peek = STDIN.peek
    if index = peek.index { |x| x == 32 || x == 10 }
      STDIN.skip(index + 1)
      return String.new(peek[0, index])
    end

    String.build do |buffer|
      loop do
        buffer.write peek
        STDIN.skip(peek.size)
        peek = STDIN.peek
        break if peek.empty?
        if index = peek.index { |x| x == 32 || x == 10 }
          buffer.write peek[0, index]
          STDIN.skip(index)
          break
        end
      end
    end
  end
end

macro internal_input(type, else_ast)
  {% if Scanner.class.has_method?(type.id) %}
    Scanner.{{type.id}}
  {% elsif type.stringify == "String" %}
    Scanner.s
  {% elsif type.stringify == "Char" %}
    Scanner.c
  {% elsif type.stringify =~ /[A-Z][a-z0-9_]*/ %}
    {{type.id}}.new(Scanner.s)
  {% elsif String.has_method?("to_#{type}".id) %}
    Scanner.s.to_{{type.id}}
  {% else %}
    {{else_ast}}
  {% end %}
end

macro internal_input_array(type, args)
  {% for i in 0...args.size %}
    %size{i} = input({{args[i]}})
  {% end %}
  {% begin %}
    {% for i in 0...args.size %} Array.new(%size{i}) { {% end %}
      input({{type.id}})
    {% for i in 0...args.size %} } {% end %}
  {% end %}
end

macro input(type)
  {% if type.is_a?(Call) %}
    {% if type.receiver.is_a?(Nop) %}
      internal_input(
        {{type.name}}, {{type.name}}(
          {% for argument in type.args %} input({{argument}}), {% end %}
        )
      )
    {% elsif type.name.stringify == "[]" %}
      internal_input_array({{type.receiver}}, {{type.args}})
    {% else %}
      input({{type.receiver}}).{{type.name.id}}(
        {% for argument in type.args %} input({{argument}}), {% end %}
      ) {{type.block}}
    {% end %}
  {% elsif type.is_a?(TupleLiteral) %}
    { {% for i in 0...type.size %} input({{type[i]}}), {% end %} }
  {% elsif type.is_a?(ArrayLiteral) %}
    [ {% for i in 0...type.size %} input({{type[i]}}), {% end %} ]
  {% elsif type.is_a?(RangeLiteral) %}
    Range.new(input({{type.begin}}), input({{type.end}}), {{type.excludes_end?}})
  {% elsif type.is_a?(If) %}
    {{type.cond}} ? input({{type.then}}) : input({{type.else}})
  {% elsif type.is_a?(Assign) %}
    {{type.target}} = input({{type.value}})
  {% else %}
    internal_input({{type.id}}, {{type.id}})
  {% end %}
end

macro input(*types)
  { {% for type in types %} input({{type}}), {% end %} }
end

macro input_column(types, size)
  {% for type, i in types %}
    %array{i} = Array({{type}}).new({{size}})
  {% end %}
  {{size}}.times do
    {% for type, i in types %}
      %array{i} << input({{type}})
    {% end %}
  end
  { {% for type, i in types %} %array{i}, {% end %} }
end

# require "./tuple/times"
struct Tuple
  def times(&block) : Nil
    {% begin %}
      {% for i in 0...@type.size %}
        {% if @type[i].has_method?(:each) %}
          self[{{i}}].each do |i{{i}}|
        {% else %}
          self[{{i}}].times do |i{{i}}|
        {% end %}
      {% end %}
      yield({% for i in 0...@type.size %} i{{i}}, {% end %})
      {% for i in 0...@type.size %} end {% end %}
    {% end %}
  end

  private class TimesIterator(T)
    include Iterator(T)

    def initialize(@n : T)
      tuple = {% begin %}
                { {% for i in 0...T.size %} T[{{i}}].zero, {% end %} }
              {% end %}
      @index = tuple.as(T)
      @first = true
    end

    def next
      if @first
        @first = false
        return @index
      end
      {% begin %}
        {%
          type = @type.type_vars[0]
          size = type.size
        %}
        {% for i in 1..size %}
          if @index[{{size - i}}] < @n[{{size - i}}] - 1
            @index = {
              {% for j in 0...size %}
                {% if j < size - i %}
                  @index[{{j}}],
                {% elsif j == size - i %}
                  @index[{{j}}] + 1,
                {% else %}
                  {{type[j]}}.zero,
                {% end %}
              {% end %}
            }
            return @index
          end
        {% end %}
        stop
      {% end %}
    end
  end

  def times
    TimesIterator(self).new(self)
  end
end

# require "./comparable/min_max"
module Comparable(T)
  def min(x : T)
    self > x ? x : self
  end

  def max(x : T)
    self < x ? x : self
  end
end

# require "./array/new"
class Array
  def self.new(sizes : Tuple(*T), initial_value) forall T
    {% begin %}
      {% for i in 0...T.size %} Array.new(sizes[{{i}}]) { {% end %}
      initial_value
      {% for i in 0...T.size %} } {% end %}
    {% end %}
  end

  def self.new(sizes : Tuple(*T), &block) forall T
    {% begin %}
      {% for i in 0...T.size %} Array.new(sizes[{{i}}]) { |%i{i}| {% end %}
      yield({% for i in 0...T.size %} %i{i}, {% end %})
      {% for i in 0...T.size %} } {% end %}
    {% end %}
  end
end

# require "./array/change"
class Array(T)
  def chmin(i : Int, value : T)
    (self[i] > value).tap do |f|
      self[i] = value if f
    end
  end

  protected def chmin(i : Int, *indexes, value)
    self[i].chmin(*indexes, value: value)
  end

  def chmin(indexes : Tuple, value)
    chmin(*indexes, value: value)
  end

  def chmax(i : Int, value : T)
    (self[i] < value).tap do |f|
      self[i] = value if f
    end
  end

  protected def chmax(i : Int, *indexes, value)
    self[i].chmax(*indexes, value: value)
  end

  def chmax(indexes : Tuple, value)
    chmax(*indexes, value: value)
  end
end

# require "/graph/decompose"
# require "../graph"
# require "./graph/edge"
struct WeightedEdge(T)
  include Comparable(WeightedEdge(T))

  property to : Int32, cost : T

  def initialize(@to, @cost : T)
  end

  def <=>(other : WeightedEdge(T))
    {cost, to} <=> {other.cost, other.to}
  end

  def to_s(io) : Nil
    io << '(' << to << ", " << cost << ')'
  end

  def inspect(io) : Nil
    io << "->#{to}(#{cost})"
  end
end

struct WeightedEdge2(T)
  include Comparable(WeightedEdge2(T))

  property from : Int32, to : Int32, cost : T

  def initialize(@from, @to, @cost : T)
  end

  def initialize(@from, edge : WeightedEdge(T))
    @to, @cost = edge.to, edge.cost
  end

  def <=>(other : WeightedEdge2(T))
    {cost, from, to} <=> {other.cost, other.from, other.to}
  end

  def reverse
    WeightedEdge2(T).new(to, from, cost)
  end

  def sort
    WeightedEdge2(T).new(*{to, from}.minmax, cost)
  end

  def to_s(io) : Nil
    io << '(' << from << ", " << to << ", " << cost << ')'
  end

  def inspect(io) : Nil
    io << from << "->" << to << '(' << cost << ')'
  end
end

struct UnweightedEdge
  property to : Int32

  def initialize(@to)
  end

  def initialize(@to, cost)
  end

  def cost
    1
  end

  def to_s(io) : Nil
    io << to
  end

  def inspect(io) : Nil
    io << "->" << to
  end
end

struct UnweightedEdge2
  property from : Int32, to : Int32

  def initialize(@from, @to)
  end

  def initialize(@from, @to, cost)
  end

  def initialize(@from, edge : UnweightedEdge)
    @to = edge.to
  end

  def cost
    1
  end

  def reverse
    UnweightedEdge2.new(to, from)
  end

  def sort
    UnweightedEdge2.new(*{to, from}.minmax)
  end

  def to_s(io) : Nil
    io << '(' << from << ", " << to << ')'
  end

  def inspect(io) : Nil
    io << from << "->" << to
  end
end

module Graph(Edge, Edge2)
  include Enumerable(Edge2)

  getter graph : Array(Array(Edge))

  def initialize(size : Int)
    @graph = Array(Array(Edge)).new(size) { [] of Edge }
  end

  def initialize(size : Int, edges : Enumerable)
    initialize(size)
    add_edges(edges)
  end

  # Add *edge*.
  abstract def <<(edge : Edge2)

  # :ditto:
  def <<(edge : Tuple)
    self << Edge2.new(*edge)
  end

  def add_edges(edges : Enumerable)
    edges.each { |edge| self << edge }
  end

  delegate size, to: @graph
  delegate :[], to: @graph

  # Yields each edge of the graph, ans returns `nil`.
  def each(&) : Nil
    (0...size).each do |v|
      self[v].each do |edge|
        yield Edge2.new(v, edge)
      end
    end
  end

  def reverse
    if self.class.directed?
      each_with_object(self.class.new(size)) do |edge, reversed|
        reversed << edge.reverse
      end
    else
      dup
    end
  end

  def to_undirected
    if self.class.directed?
      each_with_object(self.class.new(size)) do |edge, graph|
        graph << edge
        graph << edge.reverse if self.class.directed?
      end
    else
      dup
    end
  end

  def to_s(io : IO) : Nil
    io << '['
    join(", ", io) do |edge, io|
      edge.inspect io
    end
    io << ']'
  end

  def inspect(io : IO) : Nil
    io << "[\n"
    graph.each do |edges|
      io << "  " << edges << ",\n"
    end
    io << ']'
  end
end

class DirectedGraph(T)
  include Graph(WeightedEdge(T), WeightedEdge2(T))

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable(WeightedEdge2(T)))
    super
  end

  def initialize(size : Int, edges : Enumerable({Int32, Int32, T}))
    super
  end

  def <<(edge : WeightedEdge2(T))
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << WeightedEdge.new(edge.to, edge.cost)
    self
  end

  def self.weighted?
    true
  end

  def self.directed?
    true
  end
end

class UndirectedGraph(T)
  include Graph(WeightedEdge(T), WeightedEdge2(T))

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable(WeightedEdge2(T)))
    super
  end

  def initialize(size : Int, edges : Enumerable({Int32, Int32, T}))
    super
  end

  def <<(edge : WeightedEdge2(T))
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << WeightedEdge.new(edge.to, edge.cost)
    @graph[edge.to] << WeightedEdge.new(edge.from, edge.cost)
    self
  end

  def self.weighted?
    true
  end

  def self.directed?
    false
  end
end

class UnweightedDirectedGraph
  include Graph(UnweightedEdge, UnweightedEdge2)

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable)
    super
  end

  def <<(edge : UnweightedEdge2)
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << UnweightedEdge.new(edge.to)
    self
  end

  def self.weighted?
    false
  end

  def self.directed?
    true
  end
end

class UnweightedUndirectedGraph
  include Graph(UnweightedEdge, UnweightedEdge2)

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable)
    super
  end

  def <<(edge : UnweightedEdge2)
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << UnweightedEdge.new(edge.to)
    @graph[edge.to] << UnweightedEdge.new(edge.from)
    self
  end

  def each_child(vertex : Int, parent, &block) : Nil
    graph[vertex].each do |u|
      yield u if u != parent
    end
  end

  def each_child(vertex : Int, parent)
    graph[vertex].each.select { |u| u != parent }
  end

  def self.weighted?
    false
  end

  def self.directed?
    false
  end
end

# require "../datastructure/union_find"
class UnionFind
  @d : Array(Int32)

  def initialize(n : Int)
    @d = Array.new(n, -1)
  end

  def initialize(n : Int, edges : Enumerable({Int32, Int32}))
    initialize(n)
    edges.each { |u, v| unite(u, v) }
  end

  def root(x : Int)
    @d[x] < 0 ? x : (@d[x] = root(@d[x]))
  end

  def unite(x : Int, y : Int)
    x = root(x)
    y = root(y)
    return false if x == y
    x, y = y, x if @d[x] > @d[y]
    @d[x] += @d[y]
    @d[y] = x
    true
  end

  def same?(x : Int, y : Int)
    root(x) == root(y)
  end

  def size(x : Int)
    -@d[root(x)]
  end

  def groups
    groups = Hash(Int32, Set(Int32)).new { |h, k| h[k] = Set(Int32).new }
    @d.size.times do |i|
      groups[root(i)] << i
    end
    groups.values.to_set
  end
end

module Graph(Edge, Edge2)
  # Decomposes the graph into each conected components.
  def decompose : {Array(self), Array({Int32, Int32})}
    uf = UnionFind.new(size)
    each do |edge|
      uf.unite(edge.from, edge.to)
    end
    groups = uf.groups.to_a
    index = Array.new(size, {-1, -1})
    groups.each_with_index do |group, i|
      group.each_with_index do |v, j|
        index[v] = {i, j}
      end
    end

    graphs = Array.new(groups.size) { |i| self.class.new(groups[i].size) }
    if self.class.directed?
      each do |edge|
        i1, j1 = index[edge.from]
        _, j2 = index[edge.to]
        graphs[i1] << {j1, j2, edge.cost}
      end
    else
      edge_set = Set(Edge2).new
      each do |edge|
        if edge_set.add?(edge.sort)
          i1, j1 = index[edge.from]
          _, j2 = index[edge.to]
          graphs[i1] << {j1, j2, edge.cost}
        end
      end
    end
    {graphs, index}
  end
end

# require "/graph/namori_decompose"
# require "../graph"

# require "./degree"
# require "../graph"

module Graph(Edge, Edge2)
  # Returns table of indegree.
  def indegree : Array(Int32)
    each_with_object(Array.new(size, 0)) do |edge, cnt|
      cnt[edge.to] += 1
    end
  end

  # Returns table of outdegree.
  def outdegree : Array(Int32)
    each_with_object(Array.new(size, 0)) do |edge, cnt|
      cnt[edge.from] += 1
    end
  end
end

module Graph(Edge, Edge2)
  def namori_decompose : {self, Array(Int32)}
    raise ArgumentError.new unless !self.class.directed?
    raise ArgumentError.new unless size == graph.sum(&.size) // 2

    deg = Array.new(size) { |i| self[i].size }

    que = Deque(Int32).new
    flag = Array.new(size, false)
    (0...size).each do |i|
      if deg[i] == 1
        que << i
        flag[i] = true
      end
    end

    forest = self.class.new(size)
    while v = que.shift?
      self[v].each do |edge|
        next if flag[edge.to]
        deg[edge.to] -= 1
        forest << Edge2.new(v, edge)
        if deg[edge.to] == 1
          que << edge.to
          flag[edge.to] = true
        end
      end
    end

    cycle = [] of Int32
    (0...size).each do |i|
      que << i unless flag[i]
      while v = que.pop?
        next if flag[v]
        cycle << v
        flag[v] = true
        self[v].each do |edge|
          que << edge.to unless flag[edge.to]
        end
      end
    end
    {forest, cycle}
  end
end

def dfs(graph, v, p, dist, a)
  a[v] = dist
  graph[v].each do |edge|
    next if edge.to == p
    dfs(graph, edge.to, v, dist + 1, a)
  end
end

n = input(i)
edges = input({i - 1, i - 1}[n])
ans = Array(Int32?).new(n, nil)
g = UndirectedGraph.new n, edges.each_with_index.map { |(e, i)| {e[0], e[1], i} }
graphs, index_table = g.decompose
normalize = Array.new(graphs.size) { {} of Int32 => Int32 }
index_table.each_with_index { |(i, j), k| normalize[i][j] = k }

graphs.zip(normalize) do |graph, normalize|
  if graph.size != graph.graph.sum(&.size) // 2
    puts "No"; exit
  end
  forest, cycle = graph.namori_decompose

  dist = [0] * graph.size
  cycle_index = [nil.as Int32?] * graph.size
  cycle.each_with_index do |v, i|
    cycle_index[v] = i
    dfs(forest, v, -1, 0, dist)
  end

  if cycle.size == 1
    graph.each do |edge|
      d_from, d_to = dist[edge.from], dist[edge.to]
      if d_from <= d_to
        ans[edge.cost] = normalize[edge.to]
      end
    end
  elsif cycle.size == 2
    from_flag = false
    graph.each do |edge|
      d_from, d_to = dist[edge.from], dist[edge.to]
      if d_from < d_to
        ans[edge.cost] = normalize[edge.to]
      elsif d_from == d_to &&
            cycle_index[edge.from].not_nil! < cycle_index[edge.to].not_nil!
        if {edge.from, edge.to} == {cycle.first, cycle.last}
          ans[edge.cost] = normalize[from_flag ? edge.to : edge.from]
          from_flag = true
        else
          ans[edge.cost] = normalize[edge.from]
        end
      end
    end
  else
    graph.each do |edge|
      d_from, d_to = dist[edge.from], dist[edge.to]
      if d_from < d_to
        ans[edge.cost] = normalize[edge.to]
      elsif d_from == d_to &&
            cycle_index[edge.from].not_nil! < cycle_index[edge.to].not_nil!
        if {edge.from, edge.to} == {cycle.first, cycle.last}
          ans[edge.cost] = normalize[edge.to]
        else
          ans[edge.cost] = normalize[edge.from]
        end
      end
    end
  end
end

puts "Yes", ans.join('\n', &.not_nil!.succ)

yukicoder

結果

テストケース

ソースコード