結果

問題 No.1675 Strange Minimum Query
コンテスト
ユーザー hos.lyric
提出日時 2021-09-10 21:41:05
言語 D
(dmd 2.109.1)
結果
AC  
実行時間 1,062 ms / 2,000 ms
コード長 3,962 bytes
コンパイル時間 991 ms
コンパイル使用メモリ 123,080 KB
実行使用メモリ 23,784 KB
最終ジャッジ日時 2024-06-22 12:23:23
合計ジャッジ時間 23,481 ms
ジャッジサーバーID
（参考情報） 		judge5 / judge1
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 3
other AC * 34
権限があれば一括ダウンロードができます

ソースコード

diff # 

import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }
real readReal() { return readToken.to!real; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }


// T, S: monoid
// opTT: T * T -> T
// opST: S * T * int -> T
//   (s t_a) ... (s t_{b-1}) = opST(s, t_a ... t_{b-1}, b - a)
// opSS: S * S -> S
// query(a, b, s): t_a <- s t_a, ..., t_{b-1} <- s t_{b-1};
//   returns t_a ... t_{b-1}
class SegmentTree(T, S, alias opTT, alias opST, alias opSS) {
  import std.functional : binaryFun;
  alias opTTFun = binaryFun!opTT;
  alias opSTFun = opST;
  alias opSSFun = binaryFun!opSS;
  const(T) idT;
  const(S) idS;

  int n;
  T[] ts;
  S[] ss;
  this(int n_, const(T) idT, const(S) idS) {
    this.idT = idT;
    this.idS = idS;
    for (n = 1; n < n_; n <<= 1) {}
    ts = new T[n << 1];
    ss = new S[n << 1];
    ts[] = idT;
    ss[] = idS;
  }
  ref T at(int a) {
    return ts[n + a];
  }
  void build() {
    foreach_reverse (a; 1 .. n) ts[a] = opTTFun(ts[a << 1], ts[a << 1 | 1]);
  }
  T query(int a, int b, const(S) s) {
    return query(1, 0, n, a, b, s);
  }

 private:
  T query(int u, int l, int r, int a, int b, const(S) s) {
    if (a < l) a = l;
    if (b > r) b = r;
    if (a >= b) return idT;
    if (a == l && b == r) {
      ts[u] = opSTFun(s, ts[u], r - l);
      ss[u] = opSSFun(s, ss[u]);
      return ts[u];
    }
    const int uL = u << 1, uR = u << 1 | 1;
    const int mid = (l + r) >> 1;
    // speed-up: if (ss[u] != idS)
    {
      ts[uL] = opSTFun(ss[u], ts[uL], mid - l);
      ts[uR] = opSTFun(ss[u], ts[uR], r - mid);
      ss[uL] = opSSFun(ss[u], ss[uL]);
      ss[uR] = opSSFun(ss[u], ss[uR]);
      ss[u] = idS;
    }
    const T resL = query(uL, l, mid, a, b, s);
    const T resR = query(uR, mid, r, a, b, s);
    ts[u] = opTTFun(ts[uL], ts[uR]);
    return opTTFun(resL, resR);
  }
}


void main() {
  try {
    for (; ; ) {
      const N = readInt();
      const Q = readInt();
      auto L = new int[Q];
      auto R = new int[Q];
      auto B = new int[Q];
      foreach (q; 0 .. Q) {
        L[q] = readInt() - 1;
        R[q] = readInt();
        B[q] = readInt();
      }
      
      auto ans = new int[N];
      
      auto seg0 = new SegmentTree!(int, int, max, (s, t, sz) => max(s, t), max)(N, 1, 1);
      foreach (q; 0 .. Q) {
        seg0.query(L[q], R[q], B[q]);
      }
      foreach (i; 0 .. N) {
        ans[i] = seg0.query(i, i + 1, 1);
      }
      
      auto seg1 = new SegmentTree!(int, int, min, (s, t, sz) => min(s, t), min)(N, 10^^9 + 1, 10^^9 + 1);
      foreach (i; 0 .. N) {
        seg1.at(i) = ans[i];
      }
      seg1.build;
      bool ok = true;
      foreach (q; 0 .. Q) {
        ok = ok && (seg1.query(L[q], R[q], 10^^9 + 1) == B[q]);
      }
      
      if (ok) {
        foreach (i; 0 .. N) {
          if (i > 0) write(" ");
          write(ans[i]);
        }
        writeln;
      } else {
        writeln(-1);
      }
    }
  } catch (EOFException e) {
  }
}
0