結果

問題 No.1773 Love Triangle
コンテスト
ユーザー hos.lyric
提出日時 2021-12-12 06:48:21
言語 D
(dmd 2.109.1)
結果
AC  
実行時間 633 ms / 2,000 ms
コード長 4,975 bytes
コンパイル時間 734 ms
コンパイル使用メモリ 122,076 KB
実行使用メモリ 6,948 KB
最終ジャッジ日時 2024-06-22 13:38:11
合計ジャッジ時間 28,120 ms
ジャッジサーバーID
（参考情報） 		judge2 / judge3
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 3
other AC * 90
権限があれば一括ダウンロードができます

ソースコード

diff # 

import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }
real readReal() { return readToken.to!real; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }

struct ModInt(uint M_) {
  import std.conv : to;
  alias M = M_;
  uint x;
  this(ModInt a) { x = a.x; }
  this(uint x_) { x = x_ % M; }
  this(ulong x_) { x = x_ % M; }
  this(int x_) { x = ((x_ %= cast(int)(M)) < 0) ? (x_ + cast(int)(M)) : x_; }
  this(long x_) { x = cast(uint)(((x_ %= cast(long)(M)) < 0) ? (x_ + cast(long)(M)) : x_); }
  ref ModInt opAssign(T)(inout(T) a) if (is(T == uint) || is(T == ulong) || is(T == int) || is(T == long)) { return this = ModInt(a); }
  ref ModInt opOpAssign(string op, T)(T a) {
    static if (is(T == ModInt)) {
      static if (op == "+") { x = ((x += a.x) >= M) ? (x - M) : x; }
      else static if (op == "-") { x = ((x -= a.x) >= M) ? (x + M) : x; }
      else static if (op == "*") { x = cast(uint)((cast(ulong)(x) * a.x) % M); }
      else static if (op == "/") { this *= a.inv(); }
      else static assert(false);
      return this;
    } else static if (op == "^^") {
      if (a < 0) return this = inv()^^(-a);
      ModInt b = this, c = 1U;
      for (long e = a; e; e >>= 1) { if (e & 1) c *= b; b *= b; }
      return this = c;
    } else {
      return mixin("this " ~ op ~ "= ModInt(a)");
    }
  }
  ModInt inv() const {
    uint a = M, b = x; int y = 0, z = 1;
    for (; b; ) { const q = a / b; const c = a - q * b; a = b; b = c; const w = y - cast(int)(q) * z; y = z; z = w; }
    assert(a == 1); return ModInt(y);
  }
  ModInt opUnary(string op)() const {
    static if (op == "+") { return this; }
    else static if (op == "-") { ModInt a; a.x = x ? (M - x) : 0U; return a; }
    else static assert(false);
  }
  ModInt opBinary(string op, T)(T a) const { return mixin("ModInt(this) " ~ op ~ "= a"); }
  ModInt opBinaryRight(string op, T)(T a) const { return mixin("ModInt(a) " ~ op ~ "= this"); }
  bool opCast(T: bool)() const { return (x != 0U); }
  string toString() const { return x.to!string; }
}

enum MO = 998244353;
alias Mint = ModInt!MO;


uint xrand() {
  static uint x = 314159265, y = 358979323, z = 846264338, w = 327950288;
  uint t = x ^ x << 11; x = y; y = z; z = w; return w = w ^ w >> 19 ^ t ^ t >> 8;
}


void main() {
  try {
    for (; ; ) {
      const N = readInt();
      const M = readInt();
      auto U = new int[M];
      auto V = new int[M];
      auto W = new int[M];
      foreach (i; 0 .. M) {
        U[i] = readInt() - 1;
        V[i] = readInt() - 1;
        W[i] = readInt() - 1;
      }
      
      int ans;
      foreach (_; 0 .. 2) {
        auto a = new Mint[][](N, N);
        foreach (i; 0 .. M) {
          /*
            e[u]: unit vector
            E[u][v]: matrix unit
            
            a = e[u] - e[v]
            b = e[u] - e[w]
            a b' = E[u][u] - E[u][w] - E[v][u] + E[v][w]
            b a' = E[u][u] - E[u][v] - E[w][u] + E[w][v]
            a b' - b a' = E[u][v] + E[v][w] + E[w][u] - E[u][w] - E[w][v] - E[v][u]
          */
          const u = U[i];
          const v = V[i];
          const w = W[i];
          const Mint x = xrand() % MO;
          a[u][v] += x;
          a[v][w] += x;
          a[w][u] += x;
          a[u][w] -= x;
          a[w][v] -= x;
          a[v][u] -= x;
        }
        
        int r;
        foreach (h; 0 .. N) {
          foreach (u; r .. N) {
            if (a[u][h]) {
              swap(a[r], a[u]);
              break;
            }
          }
          if (a[r][h]) {
            const s = a[r][h].inv;
            foreach (j; h + 1 .. N) {
              a[r][j] *= s;
            }
            foreach (i; r + 1 .. N) {
              const t = a[i][h];
              foreach (j; h + 1 .. N) {
                a[i][j] -= t * a[r][j];
              }
            }
            ++r;
          }
        }
        chmax(ans, r);
      }
      ans /= 2;
      
      writeln(ans);
    }
  } catch (EOFException e) {
  }
}
0