結果

問題 No.2458 Line Up Charged Balls
ユーザー 👑 hos.lyrichos.lyric
提出日時 2023-09-01 22:04:23
言語 D
(dmd 2.106.1)
結果
AC  
実行時間 123 ms / 2,000 ms
コード長 4,202 bytes
コンパイル時間 2,901 ms
コンパイル使用メモリ 120,020 KB
実行使用メモリ 12,860 KB
最終ジャッジ日時 2024-06-11 03:50:50
合計ジャッジ時間 5,881 ms
ジャッジサーバーID
（参考情報） 		judge1 / judge2
このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示
入力 結果 実行時間
実行使用メモリ
testcase_00 AC 2 ms
5,248 KB
testcase_01 AC 1 ms
5,376 KB
testcase_02 AC 1 ms
5,376 KB
testcase_03 AC 1 ms
5,376 KB
testcase_04 AC 1 ms
5,376 KB
testcase_05 AC 88 ms
12,860 KB
testcase_06 AC 91 ms
12,712 KB
testcase_07 AC 1 ms
5,376 KB
testcase_08 AC 1 ms
5,376 KB
testcase_09 AC 92 ms
11,732 KB
testcase_10 AC 25 ms
5,592 KB
testcase_11 AC 2 ms
5,376 KB
testcase_12 AC 2 ms
5,376 KB
testcase_13 AC 55 ms
9,908 KB
testcase_14 AC 48 ms
9,880 KB
testcase_15 AC 28 ms
6,548 KB
testcase_16 AC 102 ms
12,288 KB
testcase_17 AC 103 ms
12,212 KB
testcase_18 AC 102 ms
12,276 KB
testcase_19 AC 104 ms
12,304 KB
testcase_20 AC 116 ms
12,252 KB
testcase_21 AC 103 ms
12,228 KB
testcase_22 AC 115 ms
12,280 KB
testcase_23 AC 123 ms
12,332 KB
testcase_24 AC 120 ms
12,264 KB
testcase_25 AC 113 ms
12,264 KB
testcase_26 AC 105 ms
12,296 KB
testcase_27 AC 114 ms
12,240 KB
権限があれば一括ダウンロードができます

ソースコード

diff # 

import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }


// class Func = TX -> TY
//   for any f, g: Func, x -> sgn(g(x) - f(x)) must be monotone
class LiChaoTree(Func) {
  import std.algorithm : swap;
  alias TX = Func.TX;
  alias TY = Func.TY;
  const(TX) L, R;
  class Tree {
    Tree l, r;
    Func f;
    this(Func f) {
      this.f = f;
    }
  }
  Tree root;

  // [L, R)
  this(TX L, TX R) {
    assert(L < R, "LiChaoTree: L < R must hold");
    this.L = L;
    this.R = R;
  }
  // Add g to the whole [L, R)
  void add(Func g) {
    root = add(root, L, R, g);
  }
  // Add g to [a, b)
  void add(TX a, TX b, Func g) {
    root = add(root, L, R, a, b, g);
  }
  // Get max at a
  TY opCall(TX a) {
    TY mx = TY.min;
    TX l = L, r = R;
    for (Tree u = root; u; ) {
      if (u.f) {
        const fX = u.f(a);
        if (mx < fX) mx = fX;
      }
      const mid = l + (r - l) / 2;
      if (a < mid) {
        u = u.l; r = mid;
      } else {
        u = u.r; l = mid;
      }
    }
    return mx;
  }

 private:
  Tree add(Tree u0, TX l, TX r, Func g) {
    if (!u0) return new Tree(g);
    TY gL = g(l), gR = g(r);
    for (Tree u = u0; ; ) {
      TY fL = u.f ? u.f(l) : TY.min, fR = u.f ? u.f(r) : TY.min;
      if (fL >= gL && fR >= gR) return u0;
      if (fL <= gL && fR <= gR) { u.f = g; return u0; }
      if (r - l == 1) { if (fL <= gL) { u.f = g; } return u0; }
      const mid = l + (r - l) / 2;
      TY fMid = u.f(mid), gMid = g(mid);
      if (fMid < gMid) {
        swap(u.f, g);
        if (!g) return u0;
        if (gL < fL) {
          if (!u.l) { u.l = new Tree(g); return u0; }
          u = u.l; r = mid; gL = fL; gR = fMid;
        } else {
          if (!u.r) { u.r = new Tree(g); return u0; }
          u = u.r; l = mid; gL = fMid; gR = fR;
        }
      } else {
        if (fL < gL) {
          if (!u.l) { u.l = new Tree(g); return u0; }
          u = u.l; r = mid; gR = gMid;
        } else {
          if (!u.r) { u.r = new Tree(g); return u0; }
          u = u.r; l = mid; gL = gMid;
        }
      }
    }
  }
  Tree add(Tree u, TX l, TX r, TX a, TX b, Func g) {
    if (b <= l || r <= a) return u;
    if (a <= l && r <= b) return add(u, l, r, g);
    if (u && u.f && u.f(l) >= g(l) && u.f(r) >= g(r)) return u;
    if (!u) u = new Tree(null);
    const mid = l + (r - l) / 2;
    u.l = add(u.l, l, mid, a, b, g);
    u.r = add(u.r, mid, r, a, b, g);
    return u;
  }
}

// y = p x + q
class Line {
  alias TX = long;
  alias TY = long;
  long p, q;
  this(long p, long q) {
    this.p = p;
    this.q = q;
  }
  TY opCall(TX x) {
    return p * x + q;
  }
}


void main() {
  try {
    for (; ; ) {
      const N = readInt;
      auto Q = new long[N];
      foreach (i; 0 .. N) {
        Q[i] = readLong;
      }
      
      const minQ = Q.minElement;
      const maxQ = Q.maxElement;
      auto lct = new LiChaoTree!Line(minQ, maxQ + 1);
      long ans = long.min;
      foreach (i; 0 .. N) {
        long res = lct(Q[i]);
        chmax(ans, res);
        chmax(res, 0);
        lct.add(new Line(Q[i], res));
      }
      writeln(ans);
    }
  } catch (EOFException e) {
  }
}
0