#994975 (D) No.2810 Have Another Go (Hard)

提出ソース

結果

問題	No.2810 Have Another Go (Hard)
ユーザー	👑 hos.lyric
提出日時	2024-07-14 08:39:15
言語	D (dmd 2.106.1)
結果	AC
実行時間	1,906 ms / 3,000 ms
コード長	6,935 bytes
コンパイル時間	3,373 ms
コンパイル使用メモリ	153,628 KB
実行使用メモリ	6,948 KB
最終ジャッジ日時	2024-07-14 08:40:37
合計ジャッジ時間	70,914 ms
ジャッジサーバーID （参考情報）	judge5 / judge6

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	1 ms 6,812 KB
testcase_01	AC	1,834 ms 6,944 KB
testcase_02	AC	1,862 ms 6,940 KB
testcase_03	AC	1,814 ms 6,944 KB
testcase_04	AC	1,906 ms 6,940 KB
testcase_05	AC	1,814 ms 6,940 KB
testcase_06	AC	1,791 ms 6,944 KB
testcase_07	AC	1,847 ms 6,940 KB
testcase_08	AC	1,821 ms 6,944 KB
testcase_09	AC	1,885 ms 6,944 KB
testcase_10	AC	1,838 ms 6,944 KB
testcase_11	AC	10 ms 6,940 KB
testcase_12	AC	10 ms 6,940 KB
testcase_13	AC	4 ms 6,940 KB
testcase_14	AC	12 ms 6,944 KB
testcase_15	AC	9 ms 6,944 KB
testcase_16	AC	376 ms 6,940 KB
testcase_17	AC	1,642 ms 6,944 KB
testcase_18	AC	974 ms 6,944 KB
testcase_19	AC	1,547 ms 6,940 KB
testcase_20	AC	222 ms 6,944 KB
testcase_21	AC	514 ms 6,944 KB
testcase_22	AC	972 ms 6,944 KB
testcase_23	AC	685 ms 6,940 KB
testcase_24	AC	1,122 ms 6,940 KB
testcase_25	AC	1,764 ms 6,940 KB
testcase_26	AC	1,811 ms 6,944 KB
testcase_27	AC	1,835 ms 6,944 KB
testcase_28	AC	1,887 ms 6,944 KB
testcase_29	AC	1,842 ms 6,940 KB
testcase_30	AC	1,824 ms 6,940 KB
testcase_31	AC	1,821 ms 6,940 KB
testcase_32	AC	1,835 ms 6,940 KB
testcase_33	AC	1,851 ms 6,940 KB
testcase_34	AC	1,827 ms 6,940 KB
testcase_35	AC	1,828 ms 6,940 KB
testcase_36	AC	1,822 ms 6,944 KB
testcase_37	AC	1,826 ms 6,940 KB
testcase_38	AC	1,829 ms 6,940 KB
testcase_39	AC	1,802 ms 6,940 KB
testcase_40	AC	1,847 ms 6,940 KB
testcase_41	AC	1,850 ms 6,940 KB
testcase_42	AC	1,758 ms 6,940 KB
testcase_43	AC	1,786 ms 6,944 KB
testcase_44	AC	1,818 ms 6,948 KB
testcase_45	AC	1,805 ms 6,944 KB
testcase_46	AC	2 ms 6,944 KB
testcase_47	AC	4 ms 6,940 KB
testcase_48	AC	6 ms 6,940 KB
testcase_49	AC	3 ms 6,940 KB
testcase_50	AC	4 ms 6,940 KB
testcase_51	AC	22 ms 6,940 KB
testcase_52	AC	11 ms 6,944 KB
testcase_53	AC	23 ms 6,940 KB
testcase_54	AC	24 ms 6,940 KB
testcase_55	AC	13 ms 6,940 KB
testcase_56	AC	27 ms 6,944 KB
testcase_57	AC	27 ms 6,940 KB
testcase_58	AC	23 ms 6,944 KB
testcase_59	AC	39 ms 6,944 KB
testcase_60	AC	27 ms 6,940 KB

権限があれば一括ダウンロードができます

ソースコード

raw source code

import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }

string COLOR(string s = "") { return "\x1b[" ~ s ~ "m"; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }

struct ModInt(uint M_) {
  import std.conv : to;
  alias M = M_;
  uint x;
  this(ModInt a) { x = a.x; }
  this(uint x_) { x = x_ % M; }
  this(ulong x_) { x = cast(uint)(x_ % M); }
  this(int x_) { x = ((x_ %= cast(int)(M)) < 0) ? (x_ + cast(int)(M)) : x_; }
  this(long x_) { x = cast(uint)(((x_ %= cast(long)(M)) < 0) ? (x_ + cast(long)(M)) : x_); }
  ref ModInt opAssign(T)(inout(T) a) if (is(T == uint) || is(T == ulong) || is(T == int) || is(T == long)) { return this = ModInt(a); }
  ref ModInt opOpAssign(string op, T)(T a) {
    static if (is(T == ModInt)) {
      static if (op == "+") { x = ((x += a.x) >= M) ? (x - M) : x; }
      else static if (op == "-") { x = ((x -= a.x) >= M) ? (x + M) : x; }
      else static if (op == "*") { x = cast(uint)((cast(ulong)(x) * a.x) % M); }
      else static if (op == "/") { this *= a.inv(); }
      else static assert(false);
      return this;
    } else static if (op == "^^") {
      if (a < 0) return this = inv()^^(-a);
      ModInt b = this, c = 1U;
      for (long e = a; e; e >>= 1) { if (e & 1) c *= b; b *= b; }
      return this = c;
    } else {
      return mixin("this " ~ op ~ "= ModInt(a)");
    }
  }
  ModInt inv() const {
    uint a = M, b = x; int y = 0, z = 1;
    for (; b; ) { const q = a / b; const c = a - q * b; a = b; b = c; const w = y - cast(int)(q) * z; y = z; z = w; }
    assert(a == 1); return ModInt(y);
  }
  ModInt opUnary(string op)() const {
    static if (op == "+") { return this; }
    else static if (op == "-") { ModInt a; a.x = x ? (M - x) : 0U; return a; }
    else static assert(false);
  }
  ModInt opBinary(string op, T)(T a) const { return mixin("ModInt(this) " ~ op ~ "= a"); }
  ModInt opBinaryRight(string op, T)(T a) const { return mixin("ModInt(a) " ~ op ~ "= this"); }
  bool opCast(T: bool)() const { return (x != 0U); }
  string toString() const { return x.to!string; }
}

enum MO = 998244353;
alias Mint = ModInt!MO;


// x^e mod rev(cs)
Mint[] powerRev(const(Mint[]) cs, long e) {
  assert(!cs.empty);
  assert(cs[0].x == 1);
  const d = cast(int)(cs.length) - 1;
  if (d == 0) {
    return [];
  } else if (d == 1) {
    return [(-cs[1])^^e];
  }
  Mint[] mul(const(Mint[]) fs, const(Mint[]) gs) {
    auto hs = new Mint[d + d - 1];
    foreach (i; 0 .. d) foreach (j; 0 .. d) {
      hs[i + j] += fs[i] * gs[j];
    }
    foreach_reverse (i; d .. d + d - 1) {
      foreach (j; 1 .. d + 1) {
        hs[i - j] -= cs[j] * hs[i];
      }
    }
    hs.length = d;
    return hs;
  }
  auto xs = new Mint[d];
  auto ys = new Mint[d];
  xs[1] = 1;
  ys[0] = 1;
  for (; ; xs = mul(xs, xs)) {
    if (e & 1) ys = mul(ys, xs);
    if (!(e >>= 1)) break;
  }
  return ys;
}

Mint linearRecurrenceAt(const(Mint[]) as, const(Mint[]) cs, long e) {
  assert(!cs.empty);
  assert(cs[0].x == 1);
  const d = cast(int)(cs.length) - 1;
  assert(as.length >= d);
  const fs = powerRev(cs, e);
  Mint ans;
  foreach (i; 0 .. d) {
    ans += fs[i] * as[i];
  }
  return ans;
}


// square matrix
Mint[][] mul(Mint[][] a, Mint[][] b) {
  const size = cast(int)(a.length);
  auto c = new Mint[][](size, size);
  foreach (i; 0 .. size) foreach (k; 0 .. size) foreach (j; 0 .. size) {
    c[i][j] += a[i][k] * b[k][j];
  }
  return c;
}
Mint[] mul(Mint[][] a, Mint[] x) {
  const size = cast(int)(a.length);
  auto y = new Mint[size];
  foreach (i; 0 .. size) foreach (j; 0 .. size) {
    y[i] += a[i][j] * x[j];
  }
  return y;
}
Mint[][] power(Mint[][] a, long e) {
  const size = cast(int)(a.length);
  auto b = new Mint[][](size, size), c = new Mint[][](size, size);
  foreach (i; 0 .. size) foreach (j; 0 .. size) b[i][j] = a[i][j];
  foreach (i; 0 .. size) foreach (j; 0 .. size) c[i][j] = (i == j) ? 1 : 0;
  for (; e; e >>= 1) {
    if (e & 1) c = mul(c, b);
    b = mul(b, b);
  }
  return c;
}


enum D = 6;
Mint[] A, C;

// [x^n] (1 - (x^1+...+x^D))^-1
Mint calc(long n) {
  return (n >= 0) ? linearRecurrenceAt(A, C, n) : Mint(0);
}

void main() {
  A = new Mint[D];
  A[0] = 1;
  foreach (n; 1 .. D) {
    A[n] = 2^^(n-1);
  }
  C = new Mint[D + 1];
  C[0] = 1;
  C[1 .. D + 1] = Mint(-1);
  debug {
    writeln(iota(20).map!(n => calc(n)));
  }
  
  try {
    for (; ; ) {
      const N = readLong;
      const M = readLong;
      const Q = readInt;
      
      Mint all;
      foreach (x; 1 .. D + 1) {
        all += calc(M * N - x) * (D + 1 - x);
      }
      debug {
        writeln("all = ", all);
      }
      
      auto a = new Mint[][](D - 1, D - 1);
      foreach (x; 1 .. D) foreach (y; 1 .. D) {
        // (C+mN)+x --> (C+(m+1)N)-y -> (C+(m+1)N)+z
        const way = calc((N-y) - x);
        foreach (z; 1 .. D) if (y + z <= D) {
          a[x - 1][z - 1] += way;
        }
      }
      a = a.power(M - 1);
      
      foreach (q; 0 .. Q) {
        const C = readLong;
        
        auto fs = new Mint[D];
        foreach (x; 1 .. D) {
          // 0 --> C-x -> C+y -...-> (C+(M-1)N)+z
          const way = calc(C-x);
          foreach (y; 1 .. D) if (x + y <= D) {
            foreach (z; 1 .. D) {
              fs[z] += way * a[y - 1][z - 1];
            }
          }
        }
        
        // gs[x] := calc(N - C - x)
        auto gs = new Mint[2*D];
        foreach (x; 0 .. 2*D) {
          gs[x] = calc(N - C - x);
        }
        
        Mint ans;
        foreach (z; 1 .. D) {
          if (C + z >= N) {
            ans += fs[z];
          } else {
            // C+z --> N-w -> (>=N)
            foreach (w; 1 .. D + 1) {
              ans += fs[z] * gs[z + w] * (D + 1 - w);
            }
          }
        }
        debug {
          writefln("C = %s: fs = %s, ans = %s", C, fs, ans);
        }
        
        ans = all - ans;
        writeln(ans);
      }
    }
  } catch (EOFException e) {
  }
}

yukicoder

結果

テストケース

ソースコード