#404164 (D) No.940 ワープ ε=ε=ε=ε=ε=│;p>д＜│

• 問題: No.940 ワープ ε=ε=ε=ε=ε=│;p>д＜│
• ユーザー: hos.lyric
• 提出日時: 2019-12-03 00:42:30
• 言語: D (dmd 2.109.1)
• 結果: WA
• 実行時間: -
• コード長: 10,711 bytes
• コンパイル時間: 1,580 ms
• コンパイル使用メモリ: 158,396 KB
• 実行使用メモリ: 370,960 KB
• 最終ジャッジ日時: 2024-06-22 03:15:52
• 合計ジャッジ時間: 41,947 ms
• ジャッジサーバーID （参考情報）: judge4 / judge5

ファイルパターン	結果
sample	AC * 4 WA * 1
other	AC * 20 TLE * 1 -- * 1

ソースコード

import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }
real readReal() { return readToken.to!real; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }

// a^-1 (mod 2^64)
long modInv(long a)
in {
  assert(a & 1, "modInv: a must be odd");
}
do {
  long b = ((a << 1) + a) ^ 2;
  b *= 2 - a * b;
  b *= 2 - a * b;
  b *= 2 - a * b;
  b *= 2 - a * b;
  return b;
}

// a^-1 (mod m)
long modInv(long a, long m)
in {
  assert(m > 0, "modInv: m > 0 must hold");
}
do {
  long b = m, x = 1, y = 0, t;
  for (; ; ) {
    t = a / b; a -= t * b;
    if (a == 0) {
      assert(b == 1 || b == -1, "modInv: gcd(a, m) != 1");
      if (b == -1) y = -y;
      return (y < 0) ? (y + m) : y;
    }
    x -= t * y;
    t = b / a; b -= t * a;
    if (b == 0) {
      assert(a == 1 || a == -1, "modInv: gcd(a, m) != 1");
      if (a == -1) x = -x;
      return (x < 0) ? (x + m) : x;
    }
    y -= t * x;
  }
}

// 2^-31 a (mod M)
long montgomery(long M)(long a) if (1 <= M && M <= 0x7fffffff && (M & 1))
in {
  assert(0 <= a && a < (M << 31), "montgomery: 0 <= a < 2^31 M must hold");
}
do {
  enum negInvM = -modInv(M) & 0x7fffffff;
  const b = (a + ((a * negInvM) & 0x7fffffff) * M) >> 31;
  return (b >= M) ? (b - M) : b;
}

// FFT on Z / M Z with Montgomery multiplication (x -> 2^31 x)
//   G: primitive 2^K-th root of unity
class FFT(long M, int K, long G)
    if (is(typeof(montgomery!(M)(0))) && K >= 0 && 0 < G && G < M) {
  import std.algorithm : swap;
  import core.bitop : bsf;

  int n, invN;
  long[] g;

  this(int n)
  in {
    assert(!(n & (n - 1)), "FFT.this: n must be a power of 2");
    assert(4 <= n && n <= 1 << K, "FFT.this: 4 <= n <= 2^K must hold");
  }
  do {
    this.n = n;
    this.invN = ((1L << 31) / n) % M;
    g.length = n + 1;
    g[0] = (1L << 31) % M;
    g[1] = (G << 31) % M;
    foreach (_; 0 .. K - bsf(n)) {
      g[1] = montgomery!(M)(g[1] * g[1]);
    }
    foreach (i; 2 .. n + 1) {
      g[i] = montgomery!(M)(g[i - 1] * g[1]);
    }
    assert(g[0] != g[n >> 1] && g[0] == g[n],
           "FFT.this: G must be a primitive 2^K-th root of unity");
    for (int i = 0, j = 0; i < n >> 1; ++i) {
      if (i < j) {
        swap(g[i], g[j]);
        swap(g[n - i], g[n - j]);
      }
      for (int m = n >> 1; (m >>= 1) && !((j ^= m) & m); ) {}
    }
  }

  void fftMontgomery(long[] x, bool inv)
  in {
    assert(x.length == n, "FFT.fftMontgomery: |x| = n must hold");
  }
  do {
    foreach_reverse (h; 0 .. bsf(n)) {
      const l = 1 << h;
      foreach (i; 0 .. n >> 1 >> h) {
        const gI = g[inv ? (n - i) : i];
        foreach (j; i << 1 << h .. ((i << 1) + 1) << h) {
          const t = montgomery!(M)(gI * x[j + l]);
          if ((x[j + l] = x[j] - t) < 0) {
            x[j + l] += M;
          }
          if ((x[j] += t) >= M) {
            x[j] -= M;
          }
        }
      }
    }
    for (int i = 0, j = 0; i < n; ++i) {
      if (i < j) {
        swap(x[i], x[j]);
      }
      for (int m = n; (m >>= 1) && !((j ^= m) & m); ) {}
    }
    if (inv) {
      foreach (i; 0 .. n) {
        x[i] = montgomery!(M)(invN * x[i]);
      }
    }
  }

  long[] convolution(long[] a, long[] b)
  in {
    assert(a.length <= n, "FFT.convolution: |a| <= n must hold");
    assert(b.length <= n, "FFT.convolution: |b| <= n must hold");
  }
  do {
    auto x = new long[n], y = new long[n];
    foreach (i; 0 .. a.length) {
      const t = a[i] % M;
      x[i] = (((t < 0) ? (t + M) : t) << 31) % M;
    }
    foreach (i; 0 .. b.length) {
      const t = b[i] % M;
      y[i] = (((t < 0) ? (t + M) : t) << 31) % M;
    }
    fftMontgomery(x, false);
    fftMontgomery(y, false);
    foreach (i; 0 .. n) {
      x[i] = montgomery!(M)(x[i] * y[i]);
    }
    fftMontgomery(x, true);
    foreach (i; 0 .. n) {
      x[i] = montgomery!(M)(x[i]);
    }
    return x;
  }
}

// P0 P1 P2 > 2^90, P0 + P1 + P2 = 2^32 + 3
enum FFT_P0 = 2013265921L;  // 2^27 15 + 1
enum FFT_P1 = 1811939329L;  // 2^26 27 + 1
enum FFT_P2 =  469762049L;  // 2^26  7 + 1
alias FFT0 = FFT!(FFT_P0, 27, 440564289L);  // 31^15
alias FFT1 = FFT!(FFT_P1, 26,  72705542L);  // 13^27
alias FFT2 = FFT!(FFT_P2, 26,      2187L);  //  3^ 7

// Convolution of a and b (indices mod fft0.n)
//   modify a and b so that 0 <= a[i] < m, 0 <= b[i] < m
long[] convolution(FFT0 fft0, FFT1 fft1, FFT2 fft2, long[] a, long[] b, long m)
in {
  assert(fft0.n == fft1.n && fft0.n == fft2.n, "convolution: fft0.n = fft1.n = fft2.n must hold");
  assert(1 <= m && m <= 0x7fffffff, "convolution: 1 <= m < 2^31 must hold");
}
do {
  enum FFT_INV01 = modInv(FFT_P0, FFT_P1);
  enum FFT_INV012 = modInv(FFT_P0 * FFT_P1, FFT_P2);
  foreach (i; 0 .. a.length) {
    if ((a[i] %= m) < 0) {
      a[i] += m;
    }
  }
  foreach (i; 0 .. b.length) {
    if ((b[i] %= m) < 0) {
      b[i] += m;
    }
  }
  const x0 = fft0.convolution(a, b);
  const x1 = fft1.convolution(a, b);
  const x2 = fft2.convolution(a, b);
  auto x = new long[fft0.n];
  foreach (i; 0 .. fft0.n) {
    auto y0 = x0[i] % FFT_P0;
    auto y1 = (FFT_INV01 * (x1[i] - y0)) % FFT_P1;
    if (y1 < 0) {
      y1 += FFT_P1;
    }
    auto y2 = (FFT_INV012 * ((x2[i] - y0 - FFT_P0 * y1) % FFT_P2)) % FFT_P2;
    if (y2 < 0) {
      y2 += FFT_P2;
    }
    x[i] = (y0 + FFT_P0 * y1 + ((FFT_P0 * FFT_P1) % m) * y2) % m;
  }
  return x;
}

struct ModInt(int M_) {
  alias M = M_;
  int x;
  this(ModInt a) { x = a.x; }
  this(long a) { x = cast(int)(a % M); if (x < 0) x += M; }
  ref ModInt opAssign(long a) { return (this = ModInt(a)); }
  ref ModInt opOpAssign(string op)(ModInt a) {
    static if (op == "+") { x += a.x; if (x >= M) x -= M; }
    else static if (op == "-") { x -= a.x; if (x < 0) x += M; }
    else static if (op == "*") { x = cast(int)((cast(long)(x) * a.x) % M); }
    else static if (op == "/") { this *= a.inv(); }
    else static assert(false);
    return this;
  }
  ref ModInt opOpAssign(string op)(long a) {
    static if (op == "^^") {
      ModInt t2 = this, te = ModInt(1);
      for (long e = a; e; e >>= 1) {
        if (e & 1) te *= t2;
        t2 *= t2;
      }
      x = cast(int)(te.x);
      return this;
    } else return mixin("this " ~ op ~ "= ModInt(a)");
  }
  ModInt inv() const {
    int a = x, b = M, y = 1, z = 0, t;
    for (; ; ) {
      t = a / b; a -= t * b;
      if (a == 0) {
        assert(b == 1 || b == -1);
        return ModInt(b * z);
      }
      y -= t * z;
      t = b / a; b -= t * a;
      if (b == 0) {
        assert(a == 1 || a == -1);
        return ModInt(a * y);
      }
      z -= t * y;
    }
  }
  ModInt opUnary(string op)() const if (op == "-") { return ModInt(-x); }
  ModInt opBinary(string op, T)(T a) const { return mixin("ModInt(this) " ~ op ~ "= a"); }
  ModInt opBinaryRight(string op)(long a) const { return mixin("ModInt(a) " ~ op ~ "= this"); }
  string toString() const { return x.to!string; }
}

enum MO = 10^^9 + 7;
alias Mint = ModInt!MO;

enum LIM = 4 * 10^^6;
Mint[] inv, fac, invFac;
void prepare() {
  inv = new Mint[LIM];
  fac = new Mint[LIM];
  invFac = new Mint[LIM];
  inv[1] = 1;
  foreach (i; 2 .. LIM) {
    inv[i] = -(Mint.M / i) * inv[cast(size_t)(Mint.M % i)];
  }
  fac[0] = invFac[0] = 1;
  foreach (i; 1 .. LIM) {
    fac[i] = fac[i - 1] * i;
    invFac[i] = invFac[i - 1] * inv[i];
  }
}
Mint binom(long n, long k) {
  if (0 <= k && k <= n) {
    assert(n < LIM);
    return fac[cast(size_t)(n)] * invFac[cast(size_t)(k)] * invFac[cast(size_t)(n - k)];
  } else {
    return Mint(0);
  }
}



void main() {
  prepare();
  
  debug {
    {
      enum n = 5;
      auto dp = new long[][][](n, n, n);
      dp[0][0][0] = 1;
      foreach (a; 0 .. n) foreach (b; 0 .. n) foreach (c; 0 .. n) {
        foreach (aa; a .. n) foreach (bb; b .. n) foreach (cc; c .. n) {
          if (a + b + c < aa + bb + cc) {
            dp[aa][bb][cc] += dp[a][b][c];
          }
        }
      }
      foreach (a; 0 .. n) {
        writeln(dp[a]);
      }
    }
    foreach (n; 1 .. 10 + 1) {
      auto a = new long[][](n + 1, n + 1);
      foreach (i; 1 .. n + 1) {
        a[i][i] = 1;
      }
      foreach (i; 1 .. n + 1) {
        foreach (j; 1 .. i) {
          const coef = binom(i, j).x;
          foreach (k; 0 .. i) {
            a[i][k] -= coef * a[j][k];
          }
        }
      }
      foreach (i; 1 .. n + 1) {
        // writeln(a[i][1 .. $]);
      }
      auto b = new long[n + 1];
      foreach (i; 1 .. n + 1) {
        b[] += a[i][];
      }
      writeln(b[1 .. $]);
    }
  }
  
  try {
    for (; ; ) {
      const X = readInt();
      const Y = readInt();
      const Z = readInt();
      
      auto f = new Mint[X + Y + Z + 1];
      foreach (n; 1 .. X + Y + Z + 1) {
        f[n] = binom(X + n - 1, n - 1) * binom(Y + n - 1, n - 1) * binom(Z + n - 1, n - 1);
      }
      debug {
        if (X + Y + Z <= 10) {
          writeln("f = ", f);
        }
      }
      debug {
        auto ff = f.dup;
        foreach (n; 1 .. X + Y + Z + 1) {
          foreach (m; 1 .. n) {
            ff[n] -= binom(n, m) * ff[m];
          }
        }
        if (X + Y + Z <= 10) {
          writeln("ff = ", ff);
        }
      }
      
      int fftn;
      for (fftn = 4; fftn <= 2 * (X + Y + Z) + 10; fftn <<= 1) {}
      auto a = new long[fftn];
      auto b = new long[fftn];
      foreach (i; 0 .. X + Y + Z + 1) {
        a[i] = (f[i] * invFac[i]).x;
        b[i] = ((-1)^^i * invFac[i]).x;
      }
      auto res = convolution(new FFT0(fftn), new FFT1(fftn), new FFT2(fftn), a, b, MO);
      debug {
        if (X + Y + Z <= 10) {
          writeln(res);
        }
      }
      Mint ans;
      foreach (i; 1 .. X + Y + Z + 1) {
        ans += fac[i] * res[i];
      }
      writeln(ans);
    }
  } catch (EOFException e) {
  }
}