#422138 (D) No.732 3PrimeCounting

• 問題: No.732 3PrimeCounting
• ユーザー: te-sh
• 提出日時: 2020-01-28 16:52:48
• 言語: D (dmd 2.109.1)
• 結果: AC
• 実行時間: 1,925 ms / 3,000 ms
• コード長: 5,038 bytes
• コンパイル時間: 1,757 ms
• コンパイル使用メモリ: 161,972 KB
• 実行使用メモリ: 6,944 KB
• 最終ジャッジ日時: 2024-06-22 04:43:32
• 合計ジャッジ時間: 22,368 ms
• ジャッジサーバーID （参考情報）: judge1 / judge5

ファイルパターン	結果
other	AC * 89

ソースコード

// URL: https://yukicoder.me/problems/no/732

import std.algorithm, std.array, std.container, std.math, std.range, std.typecons, std.string;

version(unittest) {} else
void main()
{
  int N; io.getV(N);

  auto p = Prime(N*3).array.assumeSorted;
  auto ca = new int[](N*2), cb = new int[](N*2), ans = 0L;

  foreach (b; p.upperBound(2).lowerBound(N+1)) {
    ca[] = 0;
    foreach (c; p.upperBound(b).lowerBound(N+1)) ++ca[b+c];
    foreach (i; 1..N+1) ans += ca[i*2]*cb[i*2];
    foreach (d; p.upperBound(b).lowerBound(b+N*2+1)) ++cb[d-b];
  }

  io.put(ans);
}

auto lowerBoundBy(alias conv = "a", alias comp = "a<b", R, T)(R a, T v)
{ return a.sortedTuple!(conv, comp).lowerBound(tuple(a.front, v)).map!"a[0]"; }

auto upperBoundBy(alias conv = "a", alias comp = "a<b", R, T)(R a, T v)
{ return a.sortedTuple!(conv, comp).upperBound(tuple(a.front, v)).map!"a[0]"; }

auto sortedTuple(alias conv = "a", alias comp = "a<b", R)(R a)
{
  import std.functional;
  alias convFun = unaryFun!conv, compFun = binaryFun!comp;
  return a.map!(e => tuple(e, convFun(e))).assumeSorted!((a, b) => compFun(a[1], b[1]));
}

pure T isqrt(T)(T n)
{
  static if (is(T == int)) auto max = 46341;
  else static if (is(T == long)) auto max = 3037000500L;
  return iota(T(0), max).lowerBoundBy!("a^^2", "a<=b")(n).back;
}

pure T icbrt(T)(T n)
{
  static if (is(T == int)) auto max = 1291;
  else static if (is(T == long)) auto max = 2097152L;
  return iota(T(0), max).lowerBoundBy!("a^^3", "a<=b")(n).back;
}

pure T powr(alias pred = "a*b", T, U)(T a, U n, T one)
{
  import std.functional;
  alias predFun = binaryFun!pred;
  if (n == 0) return one;
  auto r = one;
  for (; n > 0; n >>= 1) { if (n&1) r = predFun(r, a); a = predFun(a, a); }
  return r;
}
pure T powr(alias pred = "a*b", T, U)(T a, U n) { return powr!(pred, T, U)(a, n, T(1)); }

pure T extGcd(T)(T a, T b, out T x, out T y)
{
  auto g = a; x = 1; y = 0;
  if (b) { g = extGcd(b, a%b, y, x); y -= a/b*x; }
  return g;
}

struct Prime
{
  import std.bitmanip;
  struct Factor(T) { T prime; int exp; }

  const int n;
  @property array() { return primes; }
  alias array this;

  this(int n)
  {
    this.n = n;

    auto sieve = BitArray();
    sieve.length((n+1)/2);
    sieve = ~sieve;

    foreach (p; 1..(n.isqrt-1)/2+1)
      if (sieve[p])
        for (auto q = p*3+1; q < (n+1)/2; q += p*2+1)
          sieve[q] = false;

    primes = sieve.bitsSet.map!(p => cast(int)p*2+1).array;
    primes[0] = 2;
  }

  pure Factor!T[] div(T)(T x) in { assert(x > 0 && x.isqrt <= n); } do
  {
    Factor!T[] factors;
    auto t = isqrt(x);
    foreach (p; primes) {
      if (p > t) break;
      auto c = 0;
      for (; x%p == 0; x /= p) ++c;
      if (c > 0) factors ~= Factor!T(p, c);
      if (x == 1) break;
    }
    if (x > 1) factors ~= [Factor!T(x, 1)];
    return factors;
  }

  pure T[] divisors(T)(T x) in { assert(x > 0 && x.isqrt <= n); } do
  {
    auto factors = div(x);
    auto r = divisorsProc(factors, 0, 1);
    r.sort();
    return r;
  }

  private
  {
    int[] primes;

    pure T[] divisorsProc(T)(Factor!T[] factors, int i, T c)
    {
      if (i == factors.length) return [c];
      T[] r;
      foreach (j; 0..factors[i].exp+1)
        r ~= divisorsProc(factors, i+1, c*factors[i].prime^^j);
      return r;
    }
  }
}

auto io = IO!()();
import std.stdio;
struct IO(string floatFormat = "%.10f", string delimiter = " ", alias IN = stdin, alias OUT = stdout)
{
  import std.conv, std.format, std.meta, std.traits;

  auto getV(T...)(ref T v) { foreach (ref w; v) get(w); }
  auto getA(T)(size_t n, ref T v) if (hasAssignableElements!T)
  { v = new T(n); foreach (ref w; v) get(w); }
  auto getC(T...)(size_t n, ref T v)
  if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  auto getM(T)(size_t r, size_t c, ref T v)
  if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r); foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    auto getS(T)(size_t n, ref T v)
    {
      v = new T(n); foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  auto put(bool flush = false, T...)(T v)
  {
    foreach (i, w; v) { putA(w); if (i < v.length-1) OUT.write(delimiter); }
    OUT.writeln;
    static if (flush) OUT.flush();
  }
  auto putB(S, T)(bool c, S t, T f) { if (c) put(t); else put(f); }
  auto putRaw(T...)(T v) { OUT.write(v); OUT.writeln; }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;
    void nextLine() { IN.readln(buf); sp = buf.splitter; }
    auto get(T)(ref T v) { if (sp.empty) nextLine(); v = sp.front.to!T; sp.popFront(); }

    auto putR(T)(T v)
    {
      auto w = v;
      while (!w.empty) { putA(w.front); w.popFront(); if (!w.empty) OUT.write(delimiter); }
    }
    auto putA(T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putR(v);
      else if (isFloatingPoint!T) OUT.write(format(floatFormat, v));
      else OUT.write(v);
    }
  }
}