結果

問題 No.301 サイコロで確率問題 (1)
ユーザー te-shte-sh
提出日時 2020-02-21 15:19:28
言語 D
(dmd 2.106.1)
結果
AC  
実行時間 17 ms / 1,000 ms
コード長 9,309 bytes
コンパイル時間 1,800 ms
コンパイル使用メモリ 164,208 KB
実行使用メモリ 4,380 KB
最終ジャッジ日時 2023-09-04 05:54:09
合計ジャッジ時間 2,579 ms
ジャッジサーバーID
（参考情報） 		judge15 / judge13
このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示
入力 結果 実行時間
実行使用メモリ
testcase_00 AC 17 ms
4,376 KB
testcase_01 AC 15 ms
4,380 KB
権限があれば一括ダウンロードができます
コンパイルメッセージ
Main.d(384): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{floatFormat: \"%.13f\"}", double).put.putMain!(c, double).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-354(354):        instantiated from here: `putMain!(c, double)`
Main.d(19):        instantiated from here: `put!("{floatFormat: \"%.13f\"}", double)`
Main.d(384): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{delimiter: \"\"}", long, string).put.putMain!(c, long, string).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-354(354):        instantiated from here: `putMain!(c, long, string)`
Main.d(21):        instantiated from here: `put!("{delimiter: \"\"}", long, string)`

ソースコード

diff # 

// URL: https://yukicoder.me/problems/no/301
import std.algorithm, std.array, std.bitmanip, std.container, std.conv, std.format,
       std.functional, std.math, std.range, std.traits, std.typecons, std.stdio, std.string;

version(unittest) {} else
void main()
{
  int T; io.getV(T);

  auto m = Matrix!double(7, 7);
  foreach (i; 0..6) m[0][i] = 1.0/6;
  foreach (i; 0..5) m[i+1][i] = 1;
  m[0][6] = m[6][6] = 1;

  foreach (_; 0..T) {
    long N; io.getV(N);
    if (N < 100) {
      auto r = m^^N;
      io.put!`{floatFormat: "%.13f"}`(r[0][6]/(1-r[0][1..6].sum));
    } else {
      io.put!`{delimiter: ""}`(N+1, ".666666666666");
    }
  }
}

pure nothrow @safe
{
  T powr(alias pred = "a*b", T, U)(const T a, U n, T one)
    if (isIntegral!U)
  {
    auto b = T(a);
    alias predFun = binaryFun!pred;
    if (n == 0) return one;
    auto r = one;
    for (; n > 0; n >>= 1) {
      if (n&1) r = predFun(r, b);
      b = predFun(b, b);
    }
    return r;
  }
  T powr(alias pred = "a*b", T, U)(const T a, U n)
    if (isIntegral!U)
  {
    return powr!(pred, T, U)(a, n, T(1));
  }
}

struct Vector(T)
{
  size_t n;
  @property T[] array() { return a; }
  alias array this;

  pure nothrow @safe
  {
    this(size_t n, T zero = T(0))
      in { assert(n > 0); }
    do
    {
      this.n = n; this.zero = zero;
      a = new T[](n);
      if (T.init != zero)
        foreach (i; 0..n) a[i] = zero;
    }
    this(U)(U[] b, T zero = T(0))
      in { assert(b.length > 0); }
    do
    {
      n = b.length; this.zero = zero;
      static if (is(T == U)) {
        a = b;
      } else {
        a = new T[](n);
        foreach (i; 0..n) a[i] = b[i];
      }
    }
    this(ref return scope const Vector!T v)
    {
      n = v.n; zero = v.zero;
      a = new T[](n);
      foreach (i; 0..n) a[i] = v.a[i];
    }

    Vector!T dup() const
    {
      return Vector!T(this);
    }

    Vector!T opBinary(string op)(const Vector!T b) const
      if (op == "+" || op == "-")
      in { assert(n == b.n); }
    do
    {
      auto x = Vector!T(n, zero);
      foreach (i; 0..n) x[i] = mixin("a[i]"~op~"b.a[i]");
      return x;
    }
    ref Vector!T opOpAssign(string op)(const Vector!T b)
      if (op == "+" || op == "-")
      in { assert(n == b.n); }
    do
    {
      foreach (i; 0..n) mixin("a[i]"~op~"=b.a[i];");
      return this;
    }
    Vector!T opBinary(string op: "*", U)(U b) const
      if (isNumeric!T)
    {
      auto x = Vector!T(n, zero);
      foreach (i; 0..n) x[i] = a[i]*b;
      return x;
    }
    ref Vector!T opOpAssign(string op: "*", U)(U b)
      if (isNumeric!T)
    {
      foreach (i; 0..n) a[i] *= b;
      return this;
    }
    T opBinary(string op: "*")(const Vector!T b) const
      in { assert(n == b.n); }
    do
    {
      auto x = T(zero);
      foreach (i; 0..n) x += a[i]*b.a[i];
      return x;
    }
  }

  private
  {
    T[] a;
    T zero;
  }
}

pure nothrow @safe
{
  auto vector(T)(T[] a, T zero = T(0))
  {
    return Vector!T(a, zero);
  }
  T hypot2(T)(const Vector!T a)
  {
    return a*a;
  }
  pure Vector!T cross(T)(Vector!T a, Vector!T b)
    in { assert(a.n == 3 && b.n == 3); }
  do
  {
    return Vector!T([a[1]*b[2]-a[2]*b[1], a[2]*b[0]-a[0]*b[2], a[0]*b[1]-a[1]*b[0]], a.zero);
  }
}

struct Matrix(T)
{
  size_t r, c;
  @property T[][] array() { return a; }
  alias array this;

  pure nothrow @safe
  {
    static Matrix!T unit(size_t n, T zero = T(0), T one = T(1))
      in { assert(n > 0); }
    do
    {
      auto r = Matrix!T(n, n, zero, one);
      foreach (i; 0..n) r[i][i] = one;
      return r;
    }

    this(size_t r, size_t c, T zero = T(0), T one = T(1))
      in { assert(r > 0 && c > 0); }
    do
    {
      this.r = r; this.c = c; this.zero = zero; this.one = one;
      a = new T[][](r, c);
      if (T.init != zero)
        foreach (i; 0..r) foreach (j; 0..c) a[i][j] = zero;
    }
    this(U)(U[][] b, T zero = T(0), T one = T(1))
      in { assert(b.length > 0 && b[0].length > 0 && b.all!(l => l.length == b[0].length)); }
    do
    {
      r = b.length; c = b[0].length; this.zero = zero; this.one = one;
      static if (is(T == U)) {
        a = b;
      } else {
        a = new T[][](r, c);
        foreach (i; 0..r) foreach (j; 0..c) a[i][j] = b[i][j];
      }
    }
    this(ref return scope const Matrix!T v)
    {
      r = v.r; c = v.c; zero = v.zero; one = v.one;
      a = new T[][](r, c);
      foreach (i; 0..r) foreach (j; 0..c) a[i][j] = v.a[i][j];
    }

    Matrix!T dup() const
    {
      return Matrix!T(this);
    }

    bool opEquals(Matrix!T b) const
    {
      return r == b.r && c == b.c && zip(a, b.a).all!"a[0]==a[1]";
    }

    Matrix!T opBinary(string op)(const Matrix!T b) const
      if (op == "+" || op == "-")
      in { assert(r == b.r && c == b.c); }
    do
    {
      auto x = Matrix!T(r, c, zero, one);
      foreach (i; 0..r) foreach (j; 0..c) x[i][j] = mixin("a[i][j]"~op~"b.a[i][j]");
      return x;
    }
    ref Matrix!T opOpAssign(string op)(const Matrix!T b)
      if (op == "+" || op == "-")
      in { assert(r == b.r && c == b.c); }
    do
    {
      foreach (i; 0..r) foreach (j; 0..c) mixin("a[i][j]"~op~"=b.a[i][j];");
      return this;
    }
    Matrix!T opBinary(string op: "*", U)(U b) const
      if (isNumeric!U)
    {
      auto x = Matrix!T(r, c, zero, one);
      foreach (i; 0..r) foreach (j; 0..c) x[i][j] = a[i][j]*b;
      return x;
    }
    ref Matrix!T opOpAssign(string op: "*", U)(U b)
      if (isNumeric!U)
    {
      foreach (i; 0..r) foreach (j; 0..c) a[i][j] *= b;
      return this;
    }
    Matrix!T opBinary(string op: "*")(const Matrix!T b) const
      in { assert(c == b.r); }
    do
    {
      auto x = Matrix!T(r, b.c, zero, one);
      foreach (i; 0..r) foreach (j; 0..b.c) foreach (k; 0..c) x[i][j] += a[i][k]*b.a[k][j];
      return x;
    }
    ref Matrix!T opOpAssign(string op: "*")(const Matrix!T b)
      in { assert(c == b.r); }
    do
    {
      auto x = this*b;
      r = x.r; c = x.c; a = x.a;
      return this;
    }
    Vector!T opBinary(string op: "*")(const Vector!T b) const
      in { assert(c == b.n); }
    do
    {
      auto x = Vector!T(r, zero);
      foreach (i; 0..r) foreach (j; 0..c) x[i] += a[i][j]*b.a[j];
      return x;
    }
    Matrix!T opBinary(string op: "^^", U)(U n) const
      if (isIntegral!U)
      in { assert(r == c); }
    do
    {
      return powr(this, n, Matrix!T.unit(r, zero, one));
    }
  }

  private
  {
    T[][] a;
    T zero, one;
  }
}

pure nothrow @safe
{
  auto matrix(T)(T[][] a, T zero = T(0), T one = T(1))
  {
    return Matrix!T(a, zero, one);
  }

  T det(T)(Matrix!T a)
    in { assert(a.r == a.c); }
  do
  {
    auto n = a.r, b = a.dup, d = a.one;

    foreach (i; 0..n) {
      auto p = i;
      foreach (j; i+1..n)
        if (b[p][i].abs < b[j][i].abs) p = j;
      swap(b[p], b[i]);
      foreach (j; i+1..n)
        foreach (k; i+1..n)
          b[j][k] -= b[i][k]*b[j][i]/b[i][i];
      d *= b[i][i];
      if (p != i) d = -d;
    }

    return d;
  }
}

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.meta : allSatisfy;
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    mixin("const PutConf c = "~conf~"; putMain!c(v);");
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}
0