#432354 (D) No.199 星を描こう

提出ソース

結果

問題	No.199 星を描こう
ユーザー	te-sh
提出日時	2020-02-21 20:03:36
言語	D (dmd 2.106.1)
結果	AC
実行時間	2 ms / 2,000 ms
コード長	5,903 bytes
コンパイル時間	967 ms
コンパイル使用メモリ	121,096 KB
実行使用メモリ	6,944 KB
最終ジャッジ日時	2024-06-22 05:24:07
合計ジャッジ時間	1,809 ms
ジャッジサーバーID （参考情報）	judge3 / judge2

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	1 ms 6,812 KB
testcase_01	AC	1 ms 6,944 KB
testcase_02	AC	1 ms 6,940 KB
testcase_03	AC	1 ms 6,944 KB
testcase_04	AC	1 ms 6,944 KB
testcase_05	AC	1 ms 6,944 KB
testcase_06	AC	1 ms 6,940 KB
testcase_07	AC	1 ms 6,940 KB
testcase_08	AC	1 ms 6,944 KB
testcase_09	AC	1 ms 6,940 KB
testcase_10	AC	1 ms 6,944 KB
testcase_11	AC	1 ms 6,944 KB
testcase_12	AC	1 ms 6,940 KB
testcase_13	AC	1 ms 6,940 KB
testcase_14	AC	1 ms 6,944 KB
testcase_15	AC	1 ms 6,940 KB
testcase_16	AC	1 ms 6,940 KB
testcase_17	AC	1 ms 6,944 KB
testcase_18	AC	1 ms 6,940 KB
testcase_19	AC	1 ms 6,940 KB
testcase_20	AC	1 ms 6,940 KB
testcase_21	AC	1 ms 6,940 KB
testcase_22	AC	1 ms 6,940 KB
testcase_23	AC	1 ms 6,940 KB
testcase_24	AC	2 ms 6,944 KB
testcase_25	AC	1 ms 6,940 KB
testcase_26	AC	1 ms 6,944 KB
testcase_27	AC	1 ms 6,944 KB

権限があれば一括ダウンロードができます

コンパイルメッセージ

Main.d(236): Deprecation: function `Main.IO!(makeGlobal, makeGlobal).IO.put!("{}", string).put.putMain!(c, string).putMain` function requires a dual-context, which is deprecated
Main.d-mixin-206(206):        instantiated from here: `putMain!(c, string)`
Main.d(210):        instantiated from here: `put!("{}", string)`
Main.d(10):        instantiated from here: `putB!("{}", string, string)`

ソースコード

raw source code

// URL: https://yukicoder.me/problems/no/199

import std.algorithm, std.array, std.bitmanip, std.container, std.conv, std.format,
       std.functional, std.math, std.range, std.traits, std.typecons, std.stdio, std.string;

version(unittest) {} else
void main()
{
  Point[] p; io.getS!("x", "y")(5, p);
  io.putB(p.convexHull.length == 5, "YES", "NO");
}

alias Point = Point2!int;
struct Point2(T)
{
  T x, y;

  pure nothrow @nogc @safe
  {
    Point2!T opBinary(string op)(const Point2!T r) const
      if (op == "+" || op == "-")
    {
      return mixin("Point2(x"~op~"r.x, y"~op~"r.y)");
    }
    Point2!T opOpAssign(string op)(const Point2!T r)
      if (op == "+" || op == "-")
    {
      mixin("x"~op~"=r.x; y"~op~"=r.y;");
      return this;
    }
    Point2!T opBinary(string op, U)(U a) const
      if ((op == "*" || op == "/") && isIntegral!U)
    {
      return mixin("Point2(x"~op~"a, y"~op~"a)");
    }
    Point2!T opOpAssign(string op, U)(U a)
      if ((op == "*" || op == "/") && isIntegral!U)
    {
      mixin("x"~op~"=a; y"~op~"=a;");
      return this;
    }
    T opBinary(string op: "*")(const Point2!T r) const
    {
      return x*r.x+y*r.y;
    }
    T hypot2() const
    {
      return x^^2+y^^2;
    }
  }
}

pure nothrow @nogc @safe
{
  T distManhattan(T)(const Point2!T p1, const Point2!T p2)
  {
    return (p1.x-p2.x).abs + (p1.y-p2.y).abs;
  }

  T cross(T)(const Point2!T p1, const Point2!T p2)
  {
    return p1.x*p2.y - p1.y*p2.x;
  }
}

struct Point3(T)
{
  T x, y, z;

  pure nothrow @nogc @safe
  {
    Point3!T opBinary(string op)(const Point3!T r) const
      if (op == "+" || op == "-")
    {
      return mixin("Point3!T(x"~op~"r.x, y"~op~"r.y, z"~op~"r.z)");
    }
    Point3!T opOpAssign(string op)(const Point3!T r)
      if (op == "+" || op == "-")
    {
      mixin("x"~op~"=r.x; y"~op~"=r.y; z"~op~"=r.z;");
      return this;
    }
    Point3!T opBinary(string op, U)(U a) const
      if ((op == "*" || op == "/") && isIntegral!U)
    {
      return mixin("Point3!T(x"~op~"a, y"~op~"a, z"~op~"a)");
    }
    Point3!T opOpAssign(string op, U)(U a)
      if ((op == "*" || op == "/") && isIntegral!U)
    {
      mixin("x"~op~"=a; y"~op~"=a; z"~op~"=a;");
      return this;
    }
    T opBinary(string o: "*")(const Point3!T r) const
    {
      return x*r.x+y*r.y+z*r.z;
    }
    T hypot2() const
    {
      return x^^2+y^^2+z^^2;
    }
  }
}

pure nothrow @nogc @safe
{
  Point3!T cross(T)(const Point3!T p1, const Point3!T p2)
  {
    return Point3!T(p1.y*p2.z - p1.z*p2.y, p1.z*p2.x - p1.x*p2.z, p1.x*p2.y - p1.y*p2.x);
  }
}

pure nothrow @safe
{
  Point2!T[] convexHull(T)(Point2!T[] p)
  {
    p.multiSort!("a.x < b.x", "a.y < b.y");

    Point2!T[] lower;
    foreach (pi; p) {
      while (lower.length >= 2 && cross(lower[$-2]-pi, lower[$-1]-pi) <= 0)
        lower.length -= 1;
      lower ~= pi;
    }

    Point2!T[] upper;
    foreach_reverse (pi; p) {
      while (upper.length >= 2 && cross(upper[$-2]-pi, upper[$-1]-pi) <= 0)
        upper.length -= 1;
      upper ~= pi;
    }

    return (lower.dropBackOne ~ upper.dropBackOne).array;
  }

  T convexHullDiameter2(T)(Point2!T[] p)
  {
    auto n = p.length;
    size_t ps, pt;
    foreach (i; 1..n) {
      if (p[i].y > p[ps].y) ps = i;
      if (p[i].y < p[pt].y) pt = i;
    }

    auto maxD = (p[ps]-p[pt]).hypot2;
    auto i = ps, j = pt;
    do {
      auto ni = (i+1) % n, nj = (j+1) % n;
      if (cross(p[ni]-p[i], p[nj]-p[j]) < 0)
        i = ni;
      else
        j = nj;
      maxD = max(maxD, (p[i]-p[j]).hypot2);
    } while (i != ps || j != pt);

    return maxD;
  }
}

auto io = IO!()();
import std.stdio;
struct IO(alias IN = stdin, alias OUT = stdout)
{
  import std.meta : allSatisfy;
  import core.stdc.stdlib : exit;

  void getV(T...)(ref T v)
  {
    foreach (ref w; v) get(w);
  }
  void getA(T)(size_t n, ref T v)
    if (hasAssignableElements!T)
  {
    v = new T(n);
    foreach (ref w; v) get(w);
  }
  void getC(T...)(size_t n, ref T v)
    if (allSatisfy!(hasAssignableElements, T))
  {
    foreach (ref w; v) w = new typeof(w)(n);
    foreach (i; 0..n) foreach (ref w; v) get(w[i]);
  }
  void getM(T)(size_t r, size_t c, ref T v)
    if (hasAssignableElements!T && hasAssignableElements!(ElementType!T))
  {
    v = new T(r);
    foreach (ref w; v) getA(c, w);
  }
  template getS(E...)
  {
    void getS(T)(size_t n, ref T v)
    {
      v = new T(n);
      foreach (ref w; v) foreach (e; E) mixin("get(w."~e~");");
    }
  }

  const struct PutConf
  {
    bool newline = true, flush, exit;
    string floatFormat = "%.10f", delimiter = " ";
  }

  void put(alias conf = "{}", T...)(T v)
  {
    mixin("const PutConf c = "~conf~"; putMain!c(v);");
  }
  void putB(alias conf = "{}", S, T)(bool c, S t, T f)
  {
    if (c) put!conf(t);
    else put!conf(f);
  }
  void putRaw(T...)(T v)
  {
    OUT.write(v);
    OUT.writeln;
  }

  private
  {
    dchar[] buf;
    auto sp = (new dchar[](0)).splitter;

    void nextLine()
    {
      IN.readln(buf);
      sp = buf.splitter;
    }
    void get(T)(ref T v)
    {
      if (sp.empty) nextLine();
      v = sp.front.to!T;
      sp.popFront();
    }

    void putMain(PutConf c, T...)(T v)
    {
      foreach (i, w; v) {
        putOne!c(w);
        if (i+1 < v.length) OUT.write(c.delimiter);
      }
      static if (c.newline) OUT.writeln;
      static if (c.flush) OUT.flush();
      static if (c.exit) exit(0);
    }
    void putOne(PutConf c, T)(T v)
    {
      static if (isInputRange!T && !isSomeString!T) putRange!c(v);
      else static if (isFloatingPoint!T) OUT.write(format(c.floatFormat, v));
      else static if (hasMember!(T, "fprint")) v.fprint(OUT);
      else OUT.write(v);
    }
    void putRange(PutConf c, T)(T v)
    {
      auto w = v;
      while (!w.empty) {
        putOne!c(w.front); w.popFront();
        if (!w.empty) OUT.write(c.delimiter);
      }
    }
  }
}