結果

問題 No.1226 I hate Robot Arms
コンテスト
ユーザー hos.lyric
提出日時 2020-09-11 21:37:12
言語 D
(dmd 2.109.1)
結果
AC  
実行時間 563 ms / 2,000 ms
コード長 3,920 bytes
コンパイル時間 2,757 ms
コンパイル使用メモリ 164,896 KB
実行使用メモリ 20,724 KB
最終ジャッジ日時 2024-06-22 08:57:27
合計ジャッジ時間 14,999 ms
ジャッジサーバーID
（参考情報） 		judge1 / judge4
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 2
other AC * 28
権限があれば一括ダウンロードができます

ソースコード

diff # 

import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }
real readReal() { return readToken.to!real; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }


// T: monoid
// op: T * T -> T
// query(a, b): returns t_a ... t_{b-1}
class SegmentTree(T, alias op) {
  import std.functional : binaryFun;
  alias opFun = binaryFun!op;
  const(T) idT;

  int n;
  T[] ts;
  this(int n_, const(T) idT) {
    this.idT = idT;
    for (n = 1; n < n_; n <<= 1) {}
    ts = new T[n << 1];
    ts[] = idT;
  }
  this(inout(T)[] ts_, const(T) idT) {
    this.idT = idT;
    const n_ = cast(int)(ts_.length);
    for (n = 1; n < n_; n <<= 1) {}
    ts = new T[n << 1];
    ts[0 .. n] = idT;
    ts[n .. n + n_] = ts_[];
    ts[n + n_ .. n << 1] = idT;
    build();
  }
  ref T at(int a) {
    return ts[n + a];
  }
  void build() {
    foreach_reverse (a; 1 .. n) ts[a] = opFun(ts[a << 1], ts[a << 1 | 1]);
  }
  void set(int a, const(T) val) {
    ts[a += n] = val;
    for (; a >>= 1; ) ts[a] = opFun(ts[a << 1], ts[a << 1 | 1]);
  }
  void mulL(int a, const(T) val) {
    set(a, opFun(val, ts[a + n]));
  }
  void mulR(int a, const(T) val) {
    set(a, opFun(ts[a + n], val));
  }
  T query(int a, int b) const {
    T prodL = idT, prodR = idT;
    for (a += n, b += n; a < b; a >>= 1, b >>= 1) {
      if (a & 1) prodL = opFun(prodL, ts[a++]);
      if (b & 1) prodR = opFun(ts[--b], prodR);
    }
    return opFun(prodL, prodR);
  }
}


struct T {
  real r, th, sum;
}
T opTT(const(T) a, const(T) b) {
  const x = a.r * cos(a.th) + b.r * cos(a.sum + b.th);
  const y = a.r * sin(a.th) + b.r * sin(a.sum + b.th);
  return T(hypot(x, y), atan2(y, x), a.sum + b.sum);
}

void main() {
  try {
    for (; ; ) {
      const N = readInt();
      const Q = readInt();
      
      auto rs = new real[N];
      auto ths = new real[N];
      rs[] = 1.0L;
      ths[] = 0.0L;
      
      auto seg = new SegmentTree!(T, opTT)(N, T(0.0L, 0.0L, 0.0L));
      foreach (i; 0 .. N) {
        seg.at(i) = T(rs[i], ths[i], ths[i]);
      }
      seg.build;
      
      foreach (q; 0 .. Q) {
        const typ = readInt();
        switch (typ) {
          case 0: {
            const i = readInt() - 1;
            const th = readReal() / 180.0L * PI;
            ths[i] = th;
            seg.set(i, T(rs[i], ths[i], ths[i]));
          } break;
          case 1: {
            const i = readInt() - 1;
            const r = readReal();
            rs[i] = r;
            seg.set(i, T(rs[i], ths[i], ths[i]));
          } break;
          case 2: {
            const i = readInt();
            const res = seg.query(0, i);
            debug {
              writeln("res = ", res);
            }
            const x = res.r * cos(res.th);
            const y = res.r * sin(res.th);
            writefln("%.9f %.9f", x, y);
          } break;
          default: assert(false);
        }
      }
    }
  } catch (EOFException e) {
  }
}
0