結果

問題 No.1629 Sorting Integers (SUM of M)
ユーザー yuruhiya
提出日時 2021-07-30 20:43:49
言語 Crystal
(1.14.0)
結果
AC  
実行時間 33 ms / 2,000 ms
コード長 9,619 bytes
コンパイル時間 14,518 ms
コンパイル使用メモリ 295,600 KB
実行使用メモリ 11,904 KB
最終ジャッジ日時 2024-09-15 22:37:39
合計ジャッジ時間 15,073 ms
ジャッジサーバーID
（参考情報） 		judge6 / judge2
このコードへのチャレンジ
（要ログイン）
ファイルパターン 結果
sample AC * 4
other AC * 14
権限があれば一括ダウンロードができます

ソースコード

diff #
プレゼンテーションモードにする

# require "/scanner"
# ### Specifications
#
# ```plain
# Inside input macro                            | Expanded code
# ----------------------------------------------+---------------------------------------
# Uppercase string: Int32, Int64, Float64, etc. | {}.new(Scanner.s)
# s                                             | Scanner.s
# c                                             | Scanner.c
# Other lowercase string: i, i64, f, etc.       | Scanner.s.to_{}
# operator[]: type[size]                        | Array.new(input(size)) { input(type) }
# Tuple literal: {t1, t2, t3}                   | {input(t1), input(t2), input(t3)}
# Array literal: [t1, t2, t3]                   | [input(t1), input(t2), input(t3)]
# Range literal: t1..t2                         | input(t1)..input(t2)
# If: cond ? t1 : t2                            | cond ? input(t1) : input(t2)
# Assign: target = value                        | target = input(value)
# ```
#
# ### Examples
#
# Input:
# ```plain
# 5 3
# foo bar
# 1 2 3 4 5
# ```
# ```
# n, m = input(Int32, Int64) # => {5, 10i64}
# input(String, Char[m])     # => {"foo", ['b', 'a', 'r']}
# input(Int32[n])            # => [1, 2, 3, 4, 5]
# ```
# ```
# n, m = input(i, i64) # => {5, 10i64}
# input(s, c[m])       # => {"foo", ['b', 'a', 'r']}
# input(i[n])          # => [1, 2, 3, 4, 5]
# ```
#
# Input:
# ```plain
# 2 3
# 1 2 3
# 4 5 6
# ```
#
# ```
# h, w = input(i, i) # => {2, 3}
# input(i[h, w])     # => [[1, 2, 3], [4, 5, 6]]
# ```
# ```
# input(i[i][i]) # => [[1, 2, 3], [4, 5, 6]]
# ```
#
# Input:
# ```plain
# 5 3
# 3 1 4 2 5
# 1 2
# 2 3
# 3 1
# ```
# ```
# n, m = input(i, i)       # => {5, 3}
# input(i.pred[n])         # => [2, 0, 3, 1, 4]
# input({i - 1, i - 1}[m]) # => [{0, 1}, {1, 2}, {2, 0}]
# ```
#
# Input:
# ```plain
# 3
# 1 2
# 2 2
# 3 2
# ```
# ```
# input({tmp = i, tmp == 1 ? i : i.pred}[i]) # => [{1, 2}, {2, 1}, {3, 1}]
# ```
#
# Input:
# ```plain
# 3
# 1 2
# 2 3
# 3 1
# ```
# ```
# n = input(i)
# input_column({Int32, Int32}, n) # => {[1, 2, 3], [2, 3, 1]}
# ```
class Scanner
  private def self.skip_to_not_space
    peek = STDIN.peek
    not_space = peek.index { |x| x != 32 && x != 10 } || peek.size
    STDIN.skip(not_space)
  end
  def self.c
    skip_to_not_space
    STDIN.read_char.not_nil!
  end
  def self.s
    skip_to_not_space
    peek = STDIN.peek
    if index = peek.index { |x| x == 32 || x == 10 }
      STDIN.skip(index + 1)
      return String.new(peek[0, index])
    end
    String.build do |buffer|
      loop do
        buffer.write peek
        STDIN.skip(peek.size)
        peek = STDIN.peek
        break if peek.empty?
        if index = peek.index { |x| x == 32 || x == 10 }
          buffer.write peek[0, index]
          STDIN.skip(index)
          break
        end
      end
    end
  end
end
macro internal_input(type, else_ast)
  {% if Scanner.class.has_method?(type.id) %}
    Scanner.{{type.id}}
  {% elsif type.stringify == "String" %}
    Scanner.s
  {% elsif type.stringify == "Char" %}
    Scanner.c
  {% elsif type.stringify =~ /[A-Z][a-z0-9_]*/ %}
    {{type.id}}.new(Scanner.s)
  {% elsif String.has_method?("to_#{type}".id) %}
    Scanner.s.to_{{type.id}}
  {% else %}
    {{else_ast}}
  {% end %}
end
macro internal_input_array(type, args)
  {% for i in 0...args.size %}
    %size{i} = input({{args[i]}})
  {% end %}
  {% begin %}
    {% for i in 0...args.size %} Array.new(%size{i}) { {% end %}
      input({{type.id}})
    {% for i in 0...args.size %} } {% end %}
  {% end %}
end
macro input(type)
  {% if type.is_a?(Call) %}
    {% if type.receiver.is_a?(Nop) %}
      internal_input(
        {{type.name}}, {{type.name}}(
          {% for argument in type.args %} input({{argument}}), {% end %}
        )
      )
    {% elsif type.name.stringify == "[]" %}
      internal_input_array({{type.receiver}}, {{type.args}})
    {% else %}
      input({{type.receiver}}).{{type.name.id}}(
        {% for argument in type.args %} input({{argument}}), {% end %}
      ) {{type.block}}
    {% end %}
  {% elsif type.is_a?(TupleLiteral) %}
    { {% for i in 0...type.size %} input({{type[i]}}), {% end %} }
  {% elsif type.is_a?(ArrayLiteral) %}
    [ {% for i in 0...type.size %} input({{type[i]}}), {% end %} ]
  {% elsif type.is_a?(RangeLiteral) %}
    Range.new(input({{type.begin}}), input({{type.end}}), {{type.excludes_end?}})
  {% elsif type.is_a?(If) %}
    {{type.cond}} ? input({{type.then}}) : input({{type.else}})
  {% elsif type.is_a?(Assign) %}
    {{type.target}} = input({{type.value}})
  {% else %}
    internal_input({{type.id}}, {{type.id}})
  {% end %}
end
macro input(*types)
  { {% for type in types %} input({{type}}), {% end %} }
end
macro input_column(types, size)
  {% for type, i in types %}
    %array{i} = Array({{type}}).new({{size}})
  {% end %}
  {{size}}.times do
    {% for type, i in types %}
      %array{i} << input({{type}})
    {% end %}
  end
  { {% for type, i in types %} %array{i}, {% end %} }
end
# require "/math/mint"
macro static_modint(name, mod)
  struct {{name}}
    MOD = {{mod}}i64
    def self.zero
      new
    end
    def self.raw(value : Int64)
      result = new
      result.value = value
      result
    end
    macro [](*nums)
      {% verbatim do %}
        Array({{@type}}).build({{nums.size}}) do |%buffer|
          {% for num, i in nums %}
            %buffer[{{i}}] = {{@type}}.new({{num}})
          {% end %}
          {{nums.size}}
        end
      {% end %}
    end
    getter value : Int64
    def initialize
      @value = 0i64
    end
    def initialize(value)
      @value = value.to_i64 % MOD
    end
    def initialize(m : self)
      @value = m.value
    end
    protected def value=(value : Int64)
      @value = value
    end
    def ==(m : self)
      value == m.value
    end
    def ==(m)
      value == m
    end
    def + : self
      self
    end
    def - : self
      self.class.raw(value != 0 ? MOD &- value : 0i64)
    end
    def +(v)
      self + self.class.new(v)
    end
    def +(m : self)
      x = value &+ m.value
      x &-= MOD if x >= MOD
      self.class.raw(x)
    end
    def -(v)
      self - self.class.new(v)
    end
    def -(m : self)
      x = value &- m.value
      x &+= MOD if x < 0
      self.class.raw(x)
    end
    def *(v)
      self * self.class.new(v)
    end
    def *(m : self)
      self.class.new(value &* m.value)
    end
    def /(v)
      self / self.class.new(v)
    end
    def /(m : self)
      raise DivisionByZeroError.new if m.value == 0
      a, b, u, v = m.value, MOD, 1i64, 0i64
      while b != 0
        t = a // b
        a &-= t &* b
        a, b = b, a
        u &-= t &* v
        u, v = v, u
      end
      self.class.new(value &* u)
    end
    def //(v)
      self / v
    end
    def **(exponent : Int)
      t, res = self, self.class.raw(1i64)
      while exponent > 0
        res *= t if exponent & 1 == 1
        t *= t
        exponent >>= 1
      end
      res
    end
    {% for op in %w[< <= > >=] %}
      def {{op.id}}(other)
        raise NotImplementedError.new({{op}})
      end
    {% end %}
    def inv
      self.class.raw(1) // self
    end
    def succ
      self.class.raw(value != MOD &- 1 ? value &+ 1 : 0i64)
    end
    def pred
      self.class.raw(value != 0 ? value &- 1 : MOD &- 1)
    end
    def abs
      self
    end
    def abs2
      self * self
    end
    def to_i64 : Int64
      value
    end
    delegate to_s, to: @value
    delegate inspect, to: @value
  end
  {% to = ("to_" + name.stringify.downcase.gsub(/mint|modint/, "m")).id %}
  struct Int
    {% for op in %w[+ - * / //] %}
      def {{op.id}}(value : {{name}})
        {{to}} {{op.id}} value
      end
    {% end %}
    {% for op in %w[< <= > >=] %}
      def {{op.id}}(m : {{name}})
        raise NotImplementedError.new({{op}})
      end
    {% end %}
    def {{to}} : {{name}}
      {{name}}.new(self)
    end
  end
  class String
    def {{to}} : {{name}}
      {{name}}.new(self)
    end
  end
end
static_modint(Mint, 1000000007)
static_modint(Mint2, 998244353)
# require "/math/combination"
class Combination(T)
  def initialize(initial_capacity : Int = 2)
    initial_capacity += 1
    @size = 2
    @factorial = Array(T).new(initial_capacity)
    @factorial << T.new(1) << T.new(1)
    @inv = Array(T).new(initial_capacity)
    @inv << T.zero << T.new(1)
    @finv = Array(T).new(initial_capacity)
    @finv << T.new(1) << T.new(1)
    expand_until(initial_capacity)
  end
  private def expand_until(n : Int)
    while @size <= n
      @factorial << @factorial[-1] * @size
      @inv << -@inv[T::MOD % @size] * (T::MOD // @size)
      @finv << @finv[-1] * @inv[@size]
      @size += 1
    end
  end
  def factorial(n : Int)
    expand_until(n)
    @factorial.unsafe_fetch(n)
  end
  def inv(n : Int)
    expand_until(n)
    @inv.unsafe_fetch(n)
  end
  def finv(n : Int)
    expand_until(n)
    @finv.unsafe_fetch(n)
  end
  def permutation(n : Int, r : Int)
    (n < r || n < 0 || r < 0) ? T.zero : factorial(n) * finv(n - r)
  end
  def combination(n : Int, r : Int)
    (n < r || n < 0 || r < 0) ? T.zero : factorial(n) * finv(r) * finv(n - r)
  end
  def repeated_combination(n : Int, r : Int)
    (n < 0 || r < 0) ? T.zero : r == 0 ? T.new(1) : combination(n + r - 1, r)
  end
end
C = Combination(Mint).new
n = input(i)
a = input(i[9])
k = a.each_with_index.sum { |x, i|
  next 0.to_m if x == 0
  cnt = 1.to_m
  sum = n - 1
  (0...9).each do |j|
    a_j = i == j ? a[j] - 1 : a[j]
    cnt *= C.combination(sum, a_j)
    sum -= a_j
  end
  cnt * i.succ
}
puts (0...n).sum { |x|
  k * 10.to_m**x
}
הההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההההה
XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX
0