#690654 (Crystal) No.1647 Travel in Mitaru city 2

提出ソース

結果

問題	No.1647 Travel in Mitaru city 2
ユーザー	yuruhiya
提出日時	2021-08-18 10:58:06
言語	Crystal (1.11.2)
結果	AC
実行時間	77 ms / 2,500 ms
コード長	14,368 bytes
コンパイル時間	13,884 ms
コンパイル使用メモリ	296,664 KB
実行使用メモリ	30,524 KB
最終ジャッジ日時	2024-10-13 03:31:52
合計ジャッジ時間	18,810 ms
ジャッジサーバーID （参考情報）	judge5 / judge4

このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示

入力	結果	実行時間実行使用メモリ
testcase_00	AC	1 ms 6,816 KB
testcase_01	AC	2 ms 6,820 KB
testcase_02	AC	2 ms 6,820 KB
testcase_03	AC	2 ms 6,816 KB
testcase_04	AC	2 ms 6,816 KB
testcase_05	AC	2 ms 6,820 KB
testcase_06	AC	2 ms 6,820 KB
testcase_07	AC	3 ms 6,816 KB
testcase_08	AC	71 ms 26,180 KB
testcase_09	AC	59 ms 24,864 KB
testcase_10	AC	69 ms 26,264 KB
testcase_11	AC	54 ms 22,988 KB
testcase_12	AC	54 ms 21,124 KB
testcase_13	AC	61 ms 21,456 KB
testcase_14	AC	74 ms 26,784 KB
testcase_15	AC	68 ms 27,476 KB
testcase_16	AC	63 ms 25,580 KB
testcase_17	AC	54 ms 21,848 KB
testcase_18	AC	55 ms 22,436 KB
testcase_19	AC	69 ms 25,520 KB
testcase_20	AC	63 ms 25,012 KB
testcase_21	AC	70 ms 26,532 KB
testcase_22	AC	75 ms 28,604 KB
testcase_23	AC	74 ms 29,256 KB
testcase_24	AC	65 ms 25,524 KB
testcase_25	AC	68 ms 26,624 KB
testcase_26	AC	74 ms 29,368 KB
testcase_27	AC	74 ms 28,828 KB
testcase_28	AC	74 ms 30,524 KB
testcase_29	AC	77 ms 29,684 KB
testcase_30	AC	70 ms 28,112 KB
testcase_31	AC	72 ms 29,488 KB
testcase_32	AC	76 ms 28,584 KB
testcase_33	AC	65 ms 26,008 KB
testcase_34	AC	72 ms 29,208 KB
testcase_35	AC	68 ms 27,444 KB
testcase_36	AC	71 ms 29,176 KB
testcase_37	AC	75 ms 29,240 KB
testcase_38	AC	69 ms 25,920 KB
testcase_39	AC	62 ms 22,444 KB
testcase_40	AC	65 ms 24,892 KB
testcase_41	AC	61 ms 23,228 KB
testcase_42	AC	68 ms 25,168 KB
testcase_43	AC	2 ms 6,824 KB
testcase_44	AC	16 ms 16,200 KB
testcase_45	AC	48 ms 20,392 KB
testcase_46	AC	64 ms 21,504 KB
testcase_47	AC	49 ms 21,416 KB
testcase_48	AC	57 ms 19,636 KB
testcase_49	AC	51 ms 19,480 KB
testcase_50	AC	58 ms 20,256 KB

権限があれば一括ダウンロードができます

ソースコード

raw source code

# require "/template"
# require "./tuple/times"
struct Tuple
  def times(&block) : Nil
    {% begin %}
      {% for i in 0...@type.size %}
        {% if @type[i].has_method?(:each) %}
          self[{{i}}].each do |i{{i}}|
        {% else %}
          self[{{i}}].times do |i{{i}}|
        {% end %}
      {% end %}
      yield({% for i in 0...@type.size %} i{{i}}, {% end %})
      {% for i in 0...@type.size %} end {% end %}
    {% end %}
  end

  private class TimesIterator(T)
    include Iterator(T)

    def initialize(@n : T)
      tuple = {% begin %}
                { {% for i in 0...T.size %} T[{{i}}].zero, {% end %} }
              {% end %}
      @index = tuple.as(T)
      @first = true
    end

    def next
      if @first
        @first = false
        return @index
      end
      {% begin %}
        {%
          type = @type.type_vars[0]
          size = type.size
        %}
        {% for i in 1..size %}
          if @index[{{size - i}}] < @n[{{size - i}}] - 1
            @index = {
              {% for j in 0...size %}
                {% if j < size - i %}
                  @index[{{j}}],
                {% elsif j == size - i %}
                  @index[{{j}}] + 1,
                {% else %}
                  {{type[j]}}.zero,
                {% end %}
              {% end %}
            }
            return @index
          end
        {% end %}
        stop
      {% end %}
    end
  end

  def times
    TimesIterator(self).new(self)
  end
end

# require "./comparable/min_max"
module Comparable(T)
  def min(x : T)
    self > x ? x : self
  end

  def max(x : T)
    self < x ? x : self
  end
end

# require "./array/new"
class Array
  def self.new(sizes : Tuple(*T), initial_value) forall T
    {% begin %}
      {% for i in 0...T.size %} Array.new(sizes[{{i}}]) { {% end %}
      initial_value
      {% for i in 0...T.size %} } {% end %}
    {% end %}
  end

  def self.new(sizes : Tuple(*T), &block) forall T
    {% begin %}
      {% for i in 0...T.size %} Array.new(sizes[{{i}}]) { |index{{i}}| {% end %}
      yield({% for i in 0...T.size %} index{{i}}, {% end %})
      {% for i in 0...T.size %} } {% end %}
    {% end %}
  end
end

# require "./array/change"
class Array(T)
  def chmin(i : Int, value : T)
    (self[i] > value).tap do |f|
      self[i] = value if f
    end
  end

  protected def chmin(i : Int, *indexes, value)
    self[i].chmin(*indexes, value: value)
  end

  def chmin(indexes : Tuple, value)
    chmin(*indexes, value: value)
  end

  def chmax(i : Int, value : T)
    (self[i] < value).tap do |f|
      self[i] = value if f
    end
  end

  protected def chmax(i : Int, *indexes, value)
    self[i].chmax(*indexes, value: value)
  end

  def chmax(indexes : Tuple, value)
    chmax(*indexes, value: value)
  end
end

# require "./scanner"
# ### Specifications
#
# ```plain
# Inside input macro                   | Expanded code
# -------------------------------------+---------------------------------------
# Uppercase string: Int32, Int64, etc. | {}.new(Scanner.s)
# s                                    | Scanner.s
# c                                    | Scanner.c
# Other lowercase string: i, i64, etc. | Scanner.s.to_{}
# operator[]: type[size]               | Array.new(input(size)) { input(type) }
# Tuple literal: {t1, t2, t3}          | {input(t1), input(t2), input(t3)}
# Array literal: [t1, t2, t3]          | [input(t1), input(t2), input(t3)]
# Range literal: t1..t2                | input(t1)..input(t2)
# If: cond ? t1 : t2                   | cond ? input(t1) : input(t2)
# Assign: target = value               | target = input(value)
# ```
#
# ### Examples
#
# Input:
# ```plain
# 5 3
# foo bar
# 1 2 3 4 5
# ```
# ```
# n, m = input(Int32, Int64) # => {5, 10i64}
# input(String, Char[m])     # => {"foo", ['b', 'a', 'r']}
# input(Int32[n])            # => [1, 2, 3, 4, 5]
# ```
# ```
# n, m = input(i, i64) # => {5, 10i64}
# input(s, c[m])       # => {"foo", ['b', 'a', 'r']}
# input(i[n])          # => [1, 2, 3, 4, 5]
# ```
#
# Input:
# ```plain
# 2 3
# 1 2 3
# 4 5 6
# ```
#
# ```
# h, w = input(i, i) # => {2, 3}
# input(i[h, w])     # => [[1, 2, 3], [4, 5, 6]]
# ```
# ```
# input(i[i][i]) # => [[1, 2, 3], [4, 5, 6]]
# ```
#
# Input:
# ```plain
# 5 3
# 3 1 4 2 5
# 1 2
# 2 3
# 3 1
# ```
# ```
# n, m = input(i, i)       # => {5, 3}
# input(i.pred[n])         # => [2, 0, 3, 1, 4]
# input({i - 1, i - 1}[m]) # => [{0, 1}, {1, 2}, {2, 0}]
# ```
#
# Input:
# ```plain
# 3
# 1 2
# 2 2
# 3 2
# ```
# ```
# input({tmp = i, tmp == 1 ? i : i.pred}[i]) # => [{1, 2}, {2, 1}, {3, 1}]
# ```
#
# Input:
# ```plain
# 3
# 1 2
# 2 3
# 3 1
# ```
# ```
# n = input(i)
# input_column({Int32, Int32}, n) # => {[1, 2, 3], [2, 3, 1]}
# ```
class Scanner
  private def self.skip_to_not_space
    peek = STDIN.peek
    not_space = peek.index { |x| x != 32 && x != 10 } || peek.size
    STDIN.skip(not_space)
  end

  def self.c
    skip_to_not_space
    STDIN.read_char.not_nil!
  end

  def self.s
    skip_to_not_space

    peek = STDIN.peek
    if index = peek.index { |x| x == 32 || x == 10 }
      STDIN.skip(index + 1)
      return String.new(peek[0, index])
    end

    String.build do |buffer|
      loop do
        buffer.write peek
        STDIN.skip(peek.size)
        peek = STDIN.peek
        break if peek.empty?
        if index = peek.index { |x| x == 32 || x == 10 }
          buffer.write peek[0, index]
          STDIN.skip(index)
          break
        end
      end
    end
  end
end

macro internal_input(type, else_ast)
  {% if Scanner.class.has_method?(type.id) %}
    Scanner.{{type.id}}
  {% elsif type.stringify == "String" %}
    Scanner.s
  {% elsif type.stringify == "Char" %}
    Scanner.c
  {% elsif type.stringify =~ /[A-Z][a-z0-9_]*/ %}
    {{type.id}}.new(Scanner.s)
  {% elsif String.has_method?("to_#{type}".id) %}
    Scanner.s.to_{{type.id}}
  {% else %}
    {{else_ast}}
  {% end %}
end

macro internal_input_array(type, args)
  {% for i in 0...args.size %}
    %size{i} = input({{args[i]}})
  {% end %}
  {% begin %}
    {% for i in 0...args.size %} Array.new(%size{i}) { {% end %}
      input({{type.id}})
    {% for i in 0...args.size %} } {% end %}
  {% end %}
end

macro input(type)
  {% if type.is_a?(Call) %}
    {% if type.receiver.is_a?(Nop) %}
      internal_input(
        {{type.name}}, {{type.name}}(
          {% for argument in type.args %} input({{argument}}), {% end %}
        )
      )
    {% elsif type.name.stringify == "[]" %}
      internal_input_array({{type.receiver}}, {{type.args}})
    {% else %}
      input({{type.receiver}}).{{type.name.id}}(
        {% for argument in type.args %} input({{argument}}), {% end %}
      ) {{type.block}}
    {% end %}
  {% elsif type.is_a?(TupleLiteral) %}
    { {% for i in 0...type.size %} input({{type[i]}}), {% end %} }
  {% elsif type.is_a?(ArrayLiteral) %}
    [ {% for i in 0...type.size %} input({{type[i]}}), {% end %} ]
  {% elsif type.is_a?(RangeLiteral) %}
    Range.new(input({{type.begin}}), input({{type.end}}), {{type.excludes_end?}})
  {% elsif type.is_a?(If) %}
    {{type.cond}} ? input({{type.then}}) : input({{type.else}})
  {% elsif type.is_a?(Assign) %}
    {{type.target}} = input({{type.value}})
  {% else %}
    internal_input({{type.id}}, {{type.id}})
  {% end %}
end

macro input(*types)
  { {% for type in types %} input({{type}}), {% end %} }
end

macro input_column(types, size)
  {% for type, i in types %}
    %array{i} = Array({{type}}).new({{size}})
  {% end %}
  {{size}}.times do
    {% for type, i in types %}
      %array{i} << input({{type}})
    {% end %}
  end
  { {% for type, i in types %} %array{i}, {% end %} }
end

# require "/graph"
# require "./graph/edge"
struct WeightedEdge(T)
  include Comparable(WeightedEdge(T))

  property to : Int32, cost : T

  def initialize(@to, @cost : T)
  end

  def <=>(other : WeightedEdge(T))
    {cost, to} <=> {other.cost, other.to}
  end

  def to_s(io) : Nil
    io << '(' << to << ", " << cost << ')'
  end

  def inspect(io) : Nil
    io << "->#{to}(#{cost})"
  end
end

struct WeightedEdge2(T)
  include Comparable(WeightedEdge2(T))

  property from : Int32, to : Int32, cost : T

  def initialize(@from, @to, @cost : T)
  end

  def initialize(@from, edge : WeightedEdge(T))
    @to, @cost = edge.to, edge.cost
  end

  def <=>(other : WeightedEdge2(T))
    {cost, from, to} <=> {other.cost, other.from, other.to}
  end

  def reverse
    WeightedEdge2(T).new(to, from, cost)
  end

  def sort
    WeightedEdge2(T).new(*{to, from}.minmax, cost)
  end

  def to_s(io) : Nil
    io << '(' << from << ", " << to << ", " << cost << ')'
  end

  def inspect(io) : Nil
    io << from << "->" << to << '(' << cost << ')'
  end
end

struct UnweightedEdge
  property to : Int32

  def initialize(@to)
  end

  def initialize(@to, cost)
  end

  def cost
    1
  end

  def to_s(io) : Nil
    io << to
  end

  def inspect(io) : Nil
    io << "->" << to
  end
end

struct UnweightedEdge2
  property from : Int32, to : Int32

  def initialize(@from, @to)
  end

  def initialize(@from, @to, cost)
  end

  def initialize(@from, edge : UnweightedEdge)
    @to = edge.to
  end

  def cost
    1
  end

  def reverse
    UnweightedEdge2.new(to, from)
  end

  def sort
    UnweightedEdge2.new(*{to, from}.minmax)
  end

  def to_s(io) : Nil
    io << '(' << from << ", " << to << ')'
  end

  def inspect(io) : Nil
    io << from << "->" << to
  end
end

module Graph(Edge, Edge2)
  include Enumerable(Edge2)

  getter graph : Array(Array(Edge))

  def initialize(size : Int)
    @graph = Array(Array(Edge)).new(size) { [] of Edge }
  end

  def initialize(size : Int, edges : Enumerable)
    initialize(size)
    add_edges(edges)
  end

  # Add *edge*.
  abstract def <<(edge : Edge2)

  # :ditto:
  def <<(edge : Tuple)
    self << Edge2.new(*edge)
  end

  def add_edges(edges : Enumerable)
    edges.each { |edge| self << edge }
  end

  delegate size, to: @graph
  delegate :[], to: @graph

  # Yields each edge of the graph, ans returns `nil`.
  def each(&) : Nil
    (0...size).each do |v|
      self[v].each do |edge|
        yield Edge2.new(v, edge)
      end
    end
  end

  def reverse
    if self.class.directed?
      each_with_object(self.class.new(size)) do |edge, reversed|
        reversed << edge.reverse
      end
    else
      dup
    end
  end

  def to_undirected
    if self.class.directed?
      each_with_object(self.class.new(size)) do |edge, graph|
        graph << edge
        graph << edge.reverse if self.class.directed?
      end
    else
      dup
    end
  end

  def to_s(io : IO) : Nil
    io << '['
    join(", ", io) do |edge, io|
      edge.inspect io
    end
    io << ']'
  end

  def inspect(io : IO) : Nil
    io << "[\n"
    graph.each do |edges|
      io << "  " << edges << ",\n"
    end
    io << ']'
  end
end

class DirectedGraph(T)
  include Graph(WeightedEdge(T), WeightedEdge2(T))

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable(WeightedEdge2(T)))
    super
  end

  def initialize(size : Int, edges : Enumerable({Int32, Int32, T}))
    super
  end

  def <<(edge : WeightedEdge2(T))
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << WeightedEdge.new(edge.to, edge.cost)
    self
  end

  def self.weighted?
    true
  end

  def self.directed?
    true
  end
end

class UndirectedGraph(T)
  include Graph(WeightedEdge(T), WeightedEdge2(T))

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable(WeightedEdge2(T)))
    super
  end

  def initialize(size : Int, edges : Enumerable({Int32, Int32, T}))
    super
  end

  def <<(edge : WeightedEdge2(T))
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << WeightedEdge.new(edge.to, edge.cost)
    @graph[edge.to] << WeightedEdge.new(edge.from, edge.cost)
    self
  end

  def self.weighted?
    true
  end

  def self.directed?
    false
  end
end

class UnweightedDirectedGraph
  include Graph(UnweightedEdge, UnweightedEdge2)

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable)
    super
  end

  def <<(edge : UnweightedEdge2)
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << UnweightedEdge.new(edge.to)
    self
  end

  def self.weighted?
    false
  end

  def self.directed?
    true
  end
end

class UnweightedUndirectedGraph
  include Graph(UnweightedEdge, UnweightedEdge2)

  def initialize(size : Int)
    super
  end

  def initialize(size : Int, edges : Enumerable)
    super
  end

  def <<(edge : UnweightedEdge2)
    raise IndexError.new unless 0 <= edge.from < size && 0 <= edge.to < size
    @graph[edge.from] << UnweightedEdge.new(edge.to)
    @graph[edge.to] << UnweightedEdge.new(edge.from)
    self
  end

  def each_child(vertex : Int, parent, &block) : Nil
    graph[vertex].each do |u|
      yield u if u != parent
    end
  end

  def each_child(vertex : Int, parent)
    graph[vertex].each.select { |u| u != parent }
  end

  def self.weighted?
    false
  end

  def self.directed?
    false
  end
end

module Graph(Edge, Edge2)
  private class DetectCircuit(Edge, Edge2)
    def initialize(@graph : Graph(Edge, Edge2))
      @circuit = [] of Edge
      @index = Array(Int32?).new(@graph.size, nil)
      @ans = [] of Edge
    end

    private def dfs(v, prev) : Bool
      @index[v] = @circuit.size
      @graph[v].each do |edge|
        if edge.to != prev
          if i = @index[edge.to]
            @circuit << edge
            @ans = @circuit[i..]
            return true
          else
            @circuit << edge
            return true if dfs(edge.to, v)
            @circuit.pop
          end
        end
      end
      false
    end

    def solve
      @graph.size.times do |i|
        return @ans if @index[i].nil? && dfs(i, -1)
      end
      nil
    end
  end

  def detect_circuit : Array(Edge)?
    DetectCircuit.new(self).solve
  end
end

h, w, n = input(i[3])
xy = input({i - 1, i - 1}[n])

graph = UndirectedGraph(Int32).new(h + w)
xy.each_with_index do |(x, y), i|
  graph << {x, h + y, i}
end

if circuit = graph.detect_circuit
  ans = circuit.map(&.cost)
  if xy[ans[0]][1] != xy[ans[1]][1]
    ans.rotate!
  end
  puts circuit.size, ans.join(' ', &.succ)
else
  puts -1
end

yukicoder

結果

テストケース

ソースコード