結果

問題 No.2151 3 on Torus-Lohkous
ユーザー 👑 hos.lyrichos.lyric
提出日時 2022-12-03 04:37:36
言語 D
(dmd 2.106.1)
結果
AC  
実行時間 30 ms / 2,000 ms
コード長 10,927 bytes
コンパイル時間 1,866 ms
コンパイル使用メモリ 172,488 KB
実行使用メモリ 5,376 KB
最終ジャッジ日時 2024-06-22 16:56:57
合計ジャッジ時間 2,934 ms
ジャッジサーバーID
（参考情報） 		judge4 / judge1
このコードへのチャレンジ
（要ログイン）

テストケース

テストケース表示
入力 結果 実行時間
実行使用メモリ
testcase_00 AC 6 ms
5,248 KB
testcase_01 AC 7 ms
5,376 KB
testcase_02 AC 6 ms
5,376 KB
testcase_03 AC 28 ms
5,376 KB
testcase_04 AC 25 ms
5,376 KB
testcase_05 AC 6 ms
5,376 KB
testcase_06 AC 12 ms
5,376 KB
testcase_07 AC 7 ms
5,376 KB
testcase_08 AC 30 ms
5,376 KB
権限があれば一括ダウンロードができます
コンパイルメッセージ
/home/linuxbrew/.linuxbrew/opt/dmd/include/dlang/dmd/std/numeric.d(2999): Warning: cannot inline function `std.numeric.gcdImpl!uint.gcdImpl`

ソースコード

diff # 

import std.conv, std.functional, std.range, std.stdio, std.string;
import std.algorithm, std.array, std.bigint, std.bitmanip, std.complex, std.container, std.math, std.mathspecial, std.numeric, std.regex, std.typecons;
import core.bitop;

class EOFException : Throwable { this() { super("EOF"); } }
string[] tokens;
string readToken() { for (; tokens.empty; ) { if (stdin.eof) { throw new EOFException; } tokens = readln.split; } auto token = tokens.front; tokens.popFront; return token; }
int readInt() { return readToken.to!int; }
long readLong() { return readToken.to!long; }
real readReal() { return readToken.to!real; }

bool chmin(T)(ref T t, in T f) { if (t > f) { t = f; return true; } else { return false; } }
bool chmax(T)(ref T t, in T f) { if (t < f) { t = f; return true; } else { return false; } }

int binarySearch(alias pred, T)(in T[] as) { int lo = -1, hi = cast(int)(as.length); for (; lo + 1 < hi; ) { const mid = (lo + hi) >> 1; (unaryFun!pred(as[mid]) ? hi : lo) = mid; } return hi; }
int lowerBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a >= val)); }
int upperBound(T)(in T[] as, T val) { return as.binarySearch!(a => (a > val)); }

struct ModInt(uint M_) {
  import std.conv : to;
  alias M = M_;
  uint x;
  this(ModInt a) { x = a.x; }
  this(uint x_) { x = x_ % M; }
  this(ulong x_) { x = cast(uint)(x_ % M); }
  this(int x_) { x = ((x_ %= cast(int)(M)) < 0) ? (x_ + cast(int)(M)) : x_; }
  this(long x_) { x = cast(uint)(((x_ %= cast(long)(M)) < 0) ? (x_ + cast(long)(M)) : x_); }
  ref ModInt opAssign(T)(inout(T) a) if (is(T == uint) || is(T == ulong) || is(T == int) || is(T == long)) { return this = ModInt(a); }
  ref ModInt opOpAssign(string op, T)(T a) {
    static if (is(T == ModInt)) {
      static if (op == "+") { x = ((x += a.x) >= M) ? (x - M) : x; }
      else static if (op == "-") { x = ((x -= a.x) >= M) ? (x + M) : x; }
      else static if (op == "*") { x = cast(uint)((cast(ulong)(x) * a.x) % M); }
      else static if (op == "/") { this *= a.inv(); }
      else static assert(false);
      return this;
    } else static if (op == "^^") {
      if (a < 0) return this = inv()^^(-a);
      ModInt b = this, c = 1U;
      for (long e = a; e; e >>= 1) { if (e & 1) c *= b; b *= b; }
      return this = c;
    } else {
      return mixin("this " ~ op ~ "= ModInt(a)");
    }
  }
  ModInt inv() const {
    uint a = M, b = x; int y = 0, z = 1;
    for (; b; ) { const q = a / b; const c = a - q * b; a = b; b = c; const w = y - cast(int)(q) * z; y = z; z = w; }
    assert(a == 1); return ModInt(y);
  }
  ModInt opUnary(string op)() const {
    static if (op == "+") { return this; }
    else static if (op == "-") { ModInt a; a.x = x ? (M - x) : 0U; return a; }
    else static assert(false);
  }
  ModInt opBinary(string op, T)(T a) const { return mixin("ModInt(this) " ~ op ~ "= a"); }
  ModInt opBinaryRight(string op, T)(T a) const { return mixin("ModInt(a) " ~ op ~ "= this"); }
  bool opCast(T: bool)() const { return (x != 0U); }
  string toString() const { return x.to!string; }
}

enum MO = 998244353;
alias Mint = ModInt!MO;

enum LIM_INV = 2 * 10^^5 + 10;
Mint[] inv, fac, invFac;
void prepare() {
  inv = new Mint[LIM_INV];
  fac = new Mint[LIM_INV];
  invFac = new Mint[LIM_INV];
  inv[1] = 1;
  foreach (i; 2 .. LIM_INV) {
    inv[i] = -((Mint.M / i) * inv[cast(size_t)(Mint.M % i)]);
  }
  fac[0] = invFac[0] = 1;
  foreach (i; 1 .. LIM_INV) {
    fac[i] = fac[i - 1] * i;
    invFac[i] = invFac[i - 1] * inv[i];
  }
}
Mint binom(long n, long k) {
  if (n < 0) {
    if (k >= 0) {
      return (-1)^^(k & 1) * binom(-n + k - 1, k);
    } else if (n - k >= 0) {
      return (-1)^^((n - k) & 1) * binom(-k - 1, n - k);
    } else {
      return Mint(0);
    }
  } else {
    if (0 <= k && k <= n) {
      assert(n < LIM_INV);
      return fac[cast(size_t)(n)] * invFac[cast(size_t)(k)] * invFac[cast(size_t)(n - k)];
    } else {
      return Mint(0);
    }
  }
}


int root(int[] uf, int u) {
  return (uf[u] < 0) ? u : (uf[u] = uf.root(uf[u]));
}
bool connect(int[] uf, int u, int v) {
  u = uf.root(u);
  v = uf.root(v);
  if (u == v) return false;
  if (uf[u] > uf[v]) swap(u, v);
  uf[u] += uf[v];
  uf[v] = u;
  return true;
}


int stressEasy(int H, int W) {
  bool[][][] as;
  auto a = new bool[][](H, W);
  void init() {
    foreach (x; 0 .. H) a[x][] = false;
  }
  void add() {
    auto aa = new bool[][](H, W);
    foreach (x; 0 .. H) aa[x][] = a[x][];
    as ~= aa;
  }
  bool check() {
    auto uf = new int[H * W];
    uf[] = -1;
    foreach (x; 0 .. H) foreach (y; 0 .. W) if (a[x][y]) {
      if (a[(x + 1) % H][y]) uf.connect(x * W + y, ((x + 1) % H) * W + y);
      if (a[x][(y + 1) % W]) uf.connect(x * W + y, x * W + ((y + 1) % W));
    }
    int numComps;
    foreach (x; 0 .. H) foreach (y; 0 .. W) if (a[x][y]) {
      if (uf[x * W + y] < 0) ++numComps;
    }
    if (numComps != 1) return false;
    
    uf[] = -1;
    foreach (x; 0 .. H) foreach (y; 0 .. W) if (a[x][y]) {
      if (a[(x + 1) % H][y]) uf.connect(x * W + y, ((x + 1) % H) * W + y);
    }
    foreach (x; 0 .. H) foreach (y; 0 .. W) if (a[x][y]) {
      if (-uf[uf.root(x * W + y)] != 3) return false;
    }
    
    uf[] = -1;
    foreach (x; 0 .. H) foreach (y; 0 .. W) if (a[x][y]) {
      if (a[x][(y + 1) % W]) uf.connect(x * W + y, x * W + ((y + 1) % W));
    }
    foreach (x; 0 .. H) foreach (y; 0 .. W) if (a[x][y]) {
      if (-uf[uf.root(x * W + y)] != 3) return false;
    }
    
    void revX() {
      foreach (x; 0 .. H) foreach (y; 0 .. W) if (x < H - 1 - x) {
        swap(a[x][y], a[H - 1 - x][y]);
      }
    }
    void revY() {
      foreach (x; 0 .. H) foreach (y; 0 .. W) if (y < W - 1 - y) {
        swap(a[x][y], a[x][W - 1 - y]);
      }
    }
    add; revX; add; revY;
    add; revX; add; revY;
    return true;
  }
  
  foreach (x0; 0 .. H) foreach (y0; 0 .. W) {
    init;
    foreach (i; 0 .. 3) foreach (j; 0 .. 3) {
      a[(x0 + i) % H][(y0 + j) % W] = true;
    }
    check;
  }
  
  foreach (x0; 0 .. H) foreach (y0; 0 .. W) {
    init;
    foreach (i; 0 .. H * W) foreach (j; 0 .. 3) {
      a[(x0 + i) % H][(y0 + i + j) % W] = true;
    }
    check;
  }
  
  foreach (x0; 0 .. H) foreach (y0; 0 .. W) {
    init;
    foreach (i; 0 .. 3 * H * W) foreach (j; 0 .. 3) {
      a[(x0 + i) % H][(y0 + i / 3 * 3 + [0, 0, 1][i % 3] + j) % W] = true;
    }
    check;
  }
  
  foreach (x0; 0 .. H) foreach (y0; 0 .. W) {
    init;
    foreach (i; 0 .. H) foreach (j; 0 .. W) if ([1, 3, 0, 2][i % 4] != j % 4) {
      a[(x0 + i) % H][(y0 + j) % W] = true;
    }
    check;
  }
  
  return cast(int)(as.sort.uniq.array.length);
}

int[][] getCompositions(int n) {
  int[][] ret;
  void dfs(int m, int[] ps) {
    if (m == 0) {
      ret ~= ps.dup;
    } else {
      for (int p = 5; p <= m; p += 3) {
        dfs(m - p, ps ~ p);
      }
    }
  }
  dfs(n, []);
  return ret;
}
int stressHard(int H, int W) {
  const N = gcd(H, W);
  const pss = getCompositions(N / 2);
  int[][][] as;
  foreach (ps; pss) foreach (qs; pss) {
    bool check() {
      const psLen = cast(int)(ps.length);
      const qsLen = cast(int)(qs.length);
      auto psSum = new int[psLen + 1];
      auto qsSum = new int[qsLen + 1];
      foreach (i; 0 .. psLen) psSum[i + 1] = psSum[i] + ps[i];
      foreach (j; 0 .. qsLen) qsSum[j + 1] = qsSum[j] + qs[j];
      auto a = new int[][](H, W);
      foreach (x; 0 .. H) a[x][] = -1;
      foreach (s; 0 .. 2 * (H / N) * (W / N) + 1) foreach (t; 0 .. 2 * (H / N) * (W / N) + 1) {
        foreach (i; 0 .. psLen + 1) foreach (j; 0 .. qsLen + 1) {
          const x = ((((N / 2) * s + psSum[i]) - ((N / 2) * t + qsSum[j])) % H + H) % H;
          const y = ((((N / 2) * s + psSum[i]) + ((N / 2) * t + qsSum[j])) % W + W) % W;
          const color = ((s * psLen + i) + (t * qsLen + j)) & 1;
          if (!~a[x][y]) a[x][y] = color;
          if (a[x][y] != color) return false;
        }
      }
      foreach (x; 0 .. H) foreach (y; 0 .. W) if (~a[x][y]) {
        foreach (dx; -5 .. +5 + 1) foreach (dy; -5 .. +5 + 1) if (abs(dx) < 5 || abs(dy) < 5) {
          const xx = ((x + dx) % H + H) % H;
          const yy = ((y + dy) % W + W) % W;
          if (!(x == xx && y == yy)) {
            if (~a[xx][yy]) return false;
          }
        }
      }
      foreach (x; 0 .. H) foreach (y; 0 .. W) if (~a[x][y]) {
        foreach (dx; [+1, -1]) foreach (dy; [+1, -1]) {
          for (int k = 1; ; ++k) {
            const xx = ((x + dx * k) % H + H) % H;
            const yy = ((y + dy * k) % W + W) % W;
            if (~a[xx][yy]) {
              if (a[x][y] == a[xx][yy]) return false;
              if (!(k >= 5 && (k - 5) % 3 == 0)) return false;
              break;
            }
          }
        }
      }
      debug {
        writefln("stressHard(%s, %s)", H, W);
        writefln("ps = %s, qs = %s", ps, qs);
        foreach (x; 0 .. H) {
          foreach (y; 0 .. W) {
            write(".01"[a[x][y] + 1]);
          }
          writeln;
        }
      }
      foreach (x0; 0 .. H) foreach (y0; 0 .. W) {
        auto aa = new int[][](H, W);
        foreach (x; 0 .. H) foreach (y; 0 .. W) {
          aa[(x0 + x) % H][(y0 + y) % W] = a[x][y];
        }
        as ~= aa;
      }
      return true;
    }
    check;
  }
  return cast(int)(as.sort.uniq.array.length);
}


Mint easy(int H, int W, int N) {
  Mint ans;
  ans += Mint(H) * Mint(W);
  if (N >= 4) {
    ans += 2 * Mint(N);
  }
  if ((H % 3 == 0 || W % 3 == 0) && N >= 5) {
    ans += 12 * Mint(N);
  }
  if (H % 4 == 0 && W % 4 == 0) {
    ans += 16;
  }
  return ans;
}
Mint hard(int N) {
  Mint ans;
  if (N % 2 == 0) {
    Mint[2] sums;
    foreach (k; 1 .. N / 10 + 1) if ((N / 2 - 5 * k) % 3 == 0) {
      sums[k & 1] += inv[k] * binom((N / 2 - 5 * k) / 3 + k - 1, k - 1);
    }
    static foreach (s; 0 .. 2) {
      ans += (N * sums[s])^^2;
    }
  }
  return ans;
}
Mint solve(int H, int W) {
  const N = gcd(H, W);
  Mint ans;
  ans += easy(H, W, N);
  ans += hard(N);
  return ans;
}


void main() {
  prepare;
  
  /*
  debug {{
    enum lim = 40;
    foreach (H; 4 .. lim + 1) foreach (W; 4 .. lim + 1) {
      const str = stressEasy(H, W);
      const eas = easy(H, W, gcd(H, W));
      assert(str == eas.x, format("%s %s: %s %s", H, W, str, eas));
      writefln("DONE H = %s, W = %s", H, W);
      stdout.flush;
    }
  }}
  //*/
  /*
  debug {{
    enum lim = 50;
    foreach (H; 4 .. lim + 1) foreach (W; 4 .. lim + 1) {
      const str = stressHard(H, W);
      const har = hard(gcd(H, W));
      assert(str == har.x, format("%s %s: %s %s", H, W, str, har));
      writefln("DONE H = %s, W = %s", H, W);
      stdout.flush;
    }
  }}
  //*/
  
  try {
    for (; ; ) {
      const numCases = readInt;
      foreach (caseId; 0 .. numCases) {
        const H = readInt;
        const W = readInt;
        
        const ans = solve(H, W);
        writeln(ans);
      }
    }
  } catch (EOFException e) {
  }
}
0